Ukryte funkcje plików wsadowych systemu Windows

Jakie są mniej znane, ale ważne i przydatne funkcje plików wsadowych systemu Windows?

Wytyczne:

• Jedna funkcja na odpowiedź
• Podaj zarówno krótki opis funkcji, jak i przykład , a nie tylko link do dokumentacji
• Ogranicz odpowiedzi do natywnej funkcjonalności , tzn. Nie wymaga dodatkowego oprogramowania, takiego jak Windows Resource Kit

Wyjaśnienie: Odwołamy się tutaj do skryptów przetwarzanych przez cmd.exe, który jest domyślny w wariantach WinNT.

(Zobacz także: Pliki wsadowe systemu Windows: .bat vs. .cmd? )

Kontynuacja linii:

call C:\WINDOWS\system32\ntbackup.exe ^
    backup ^
    /V:yes ^
    /R:no ^
    /RS:no ^
    /HC:off ^
    /M normal ^
    /L:s ^
    @daily.bks ^
    /F daily.bkf

PUSHD path

Przechodzi do katalogu określonego ścieżką .

POPD

Przenosi Cię z powrotem do katalogu, z którego „wypchnąłeś”.

Nie jestem pewien, jak przydatne byłoby to w pliku wsadowym , ale jest to bardzo wygodne polecenie do użycia w wierszu polecenia:

C:\some_directory> start .

Spowoduje to otwarcie Eksploratora Windows w folderze „some_directory”.

Uważam, że to świetna oszczędność czasu.

Zawsze miałem trudności z czytaniem komentarzy oznaczonych słowem kluczowym w każdej linii:

REM blah blah blah

Łatwiej czytać:

:: blah blah blah

Zmienne podciągi:

> set str=0123456789
> echo %str:~0,5%
01234
> echo %str:~-5,5%
56789
> echo %str:~3,-3%
3456

Polecenie FOR ! Chociaż nienawidzę pisania plików wsadowych, jestem za to wdzięczny.

FOR /F "eol=; tokens=2,3* delims=, " %i in (myfile.txt) do @echo %i %j %k

analizuje każdą linię w pliku myfile.txt, ignorując linie rozpoczynające się średnikiem, przekazując drugi i trzeci token z każdej linii do ciała for, z tokenami oddzielonymi przecinkami i / lub spacjami. Zauważ, że dla instrukcji body referencja% i pozwala uzyskać drugi token,% j, aby uzyskać trzeci token, a% k, aby uzyskać wszystkie pozostałe tokeny po 3.

Możesz także użyć tego do iteracji katalogów, zawartości katalogu itp.

Zamiast zaśmiecać skrypt za pomocą linii REM lub ::, na górze każdego skryptu wykonuję następujące czynności:

@echo OFF
goto :START

Description of the script.

Usage:
   myscript -parm1|parm2 > result.txt

:START

Zwróć uwagę, jak możesz używać znaków potoku i przekierowania bez ucieczki przed nimi.

Ścieżka (z dyskiem), w której znajduje się skrypt: ~ dp0

set BAT_HOME=%~dp0
echo %BAT_HOME%
cd %BAT_HOME%

Fragment% ~ dp0 został już wspomniany, ale w rzeczywistości jest więcej: znak (i) po ~ definiują wyodrębniane informacje.
Brak litery powoduje zwrócenie nazwy pliku poprawki
d - zwraca literę dysku
p - zwraca ścieżkę
s - zwraca krótką ścieżkę
x - zwraca rozszerzenie pliku
Więc jeśli wykonasz skrypt test.bat poniżej z c: \ Temp \ długa nazwa katalogu \ folder,

@echo off
echo %0
echo %~d0
echo %~p0
echo %~dp0
echo %~x0
echo %~s0
echo %~sp0

otrzymujesz następujące dane wyjściowe

test
c:
\Temp\long dir name\
c:\Temp\long dir name\
.bat
c:\Temp\LONGDI~1\test.bat
\Temp\LONGDI~1\

A jeśli parametr zostanie przekazany do skryptu, jak w
teście c: \ temp \ mysrc \ test.cpp,
te same manipulacje można wykonać za pomocą zmiennej% 1.

Ale wynik rozszerzenia% 0 zależy od lokalizacji!
Na „najwyższym poziomie” partii rozwija się do bieżącej nazwy pliku partii.
W funkcji (wywołaniu) rozwija się do nazwy funkcji.

@echo off
echo %0
call :test
goto :eof

:test
echo %0
echo %~0
echo %~n0

Dane wyjściowe to (plik wsadowy jest uruchamiany z myBatch.bat)

myBatch.bat
:test
:test
myBatch

Używając CALL, EXIT / B, SETLOCAL i ENDLOCAL możesz implementować podprogramy ze zmiennymi lokalnymi.

przykład:

@echo off

set x=xxxxx
call :sub 10
echo %x%
exit /b

:sub
setlocal
set /a x=%1 + 1
echo %x%
endlocal
exit /b

To zostanie wydrukowane

11
xxxxx

nawet jeśli: sub modyfikuje x.

Podstępna sztuczka, aby czekać N sekund (nie jest częścią cmd.exe, ale nie jest dodatkowym oprogramowaniem, ponieważ jest dostarczana z Windows), zobacz linię ping. Potrzebujesz pingów N + 1, ponieważ pierwszy ping gaśnie bez opóźnień.

    echo %time%
    call :waitfor 5
    echo %time%
    goto :eof
:waitfor
    setlocal
    set /a "t = %1 + 1"
    >nul ping 127.0.0.1 -n %t%
    endlocal
    goto :eof

Ucieczka przed „hydrauliką”:

echo ^| ^< ^> ^& ^\ ^^

Zdolność do uruchamiania poleceń i przetwarzania danych wyjściowych (takich jak backticks z „$ ()” w bash).

for /f %i in ('dir /on /b *.jpg') do echo --^> %i

Jeśli w nazwach plików są spacje, użyj tego:

for /f "tokens=*" %i in ('dir /on /b *.jpg') do echo --^> %i

Tworzenie pustego pliku:

> copy nul filename.ext

Aby ukryć wszystkie dane wyjściowe polecenia, przekieruj do> nul 2> & 1.

Na przykład niektóre programy wiersza polecenia wyświetlają dane wyjściowe, nawet jeśli przekierujesz do> nul. Ale jeśli przekierujesz dane wyjściowe jak w poniższym wierszu, wszystkie dane wyjściowe zostaną stłumione.

PSKILL NOTEPAD >nul 2>&1

EDYCJA: Zobacz Ignorowanie danych wyjściowych polecenia, aby uzyskać wyjaśnienie, jak to działa.

PAUSE

Zatrzymuje wykonanie i wyświetla następujący monit:

Naciśnij dowolny klawisz, aby kontynuować . . .

Przydatne, jeśli chcesz uruchomić partię, klikając ją dwukrotnie w Eksploratorze Windows i chcesz zobaczyć dane wyjściowe, a nie tylko flash okna poleceń.

Odpowiednik bash (i innych powłok)

echo -n Hello # or
echo Hello\\c

która wypisuje „ Hello” bez końcowego znaku nowej linii. Hack cmd, aby to zrobić:

<nul set /p any-variable-name=Hello

set /pto sposób na monitowanie użytkownika o wprowadzenie danych. Emituje podany ciąg, a następnie czeka (w tym samym wierszu, tj. Bez CRLF) na wpisanie przez użytkownika odpowiedzi.

<nulpo prostu potokuje pustą odpowiedź na set /ppolecenie, więc wynikiem netto jest emitowany ciąg zachęty. (Zastosowana zmienna pozostaje niezmieniona z powodu pustej odpowiedzi).

Problemy są następujące: Wyprowadzenie wiodącego znaku równości nie jest możliwe, a w systemie Vista wiodące białe znaki są usuwane, ale nie na XP.

Wyszukaj i zamień podczas ustawiania zmiennych środowiskowych:

> @set fname=%date:/=%

... usuwa „/” z daty do użycia w nazwach plików ze znacznikami czasu.

i podciągi też ...

> @set dayofweek=%fname:~0,3%

Arytmetyka liczb całkowitych:

> SET /A result=10/3 + 1
4

Separatory poleceń:

cls & dir
copy a b && echo Success
copy a b || echo Failure

W drugim wierszu polecenie po && działa tylko wtedy, gdy pierwsze polecenie zakończy się powodzeniem.

W 3. linii polecenie po || działa tylko wtedy, gdy pierwsze polecenie nie powiodło się.

Wypisz pusty wiersz:

echo.

Możesz połączyć łańcuchy instrukcji if, aby uzyskać efekt podobny do zwarcia logicznego „i”.

if foo if bar baz

Aby szybko przekonwertować plik tekstowy Unicode (16bit / char) na plik ASCII DOS (8bit / char).

C:\> type unicodeencoded.txt > dosencoded.txt

jako bonus, jeśli to możliwe, postacie są poprawnie zmapowane.

jeśli struktura bloku:

if "%VS90COMNTOOLS%"=="" (
  echo: Visual Studio 2008 is not installed
  exit /b
)

Opóźnione rozwinięcie zmiennych (z podciągnięciami dla dokładności):

    @echo off
    setlocal enableextensions enabledelayedexpansion
    set full=/u01/users/pax
:loop1
    if not "!full:~-1!" == "/" (
        set full2=!full:~-1!!full2!
        set full=!full:~,-1!
        goto :loop1
    )
    echo !full!
    endlocal

Nie zapewnia dużej funkcjonalności, ale możesz użyć polecenia tytuł do kilku zastosowań, takich jak zapewnienie statusu długiego skryptu na pasku zadań lub po prostu w celu zwiększenia opinii użytkowników.

@title Searching for ...
:: processing search
@title preparing search results
:: data processing

Nie masz pod ręką edytora i musisz utworzyć plik wsadowy?

copy con test.bat

Po prostu wpisz polecenia i naciśnij klawisz Enter, aby wyświetlić nowy wiersz. Naciśnij Ctrl-Z i Enter, aby zamknąć plik.

Przykładem strun na odejmowanie datei timeuzyskać plik o nazwie „YYYY-MM-DD HH: MM: SS.txt”

echo test > "%date:~0,4%-%date:~5,2%-%date:~8,2% %time:~0,2%_%time:~3,2%_%time:~6,2%.txt"

Używam, coloraby wskazać, czy mój skrypt zakończył się sukcesem, nie powiódł się, czy też muszę wprowadzić dane, zmieniając kolor tekstu i tła. To naprawdę pomaga, gdy masz maszynę w zasięgu wzroku, ale dość daleko

kolor XY

gdzie X i Y to wartość szesnastkowa od 0do F, gdzie X - tło, Y - tekst, gdy X = Y kolor się nie zmieni.

kolor Z

zmienia kolor tekstu na „Z” i ustawia czarne tło, „kolor 0” nie będzie działać

dla nazw kolorów zadzwoń

kolor ?

Pełna kontrola nad danymi wyjściowymi za pomocą odstępów i znaków zmiany znaczenia:

echo.    ^<resourceDir^>/%basedir%/resources^</resourceDir^>

SoftwareSedi wspomniał już o poleceniu for, ale powiem o nim ponownie, ponieważ jest bardzo potężny.

Poniższe dane wyjściowe przedstawiają bieżącą datę w formacie RRRRMMDD, używam jej do generowania katalogów kopii zapasowych.

for /f "tokens=2-4 delims=/- " %a in ('DATE/T') do echo %c%b%a