Perl
Postanowiłem być trochę antykonkurencyjnym i pokazać, jak normalnie zakodowałbyś taki problem w Perlu.
Na końcu znajduje się również 46 (łącznie) wpis do code-golfa.
Te pierwsze trzy przykłady zaczynają się od tego nagłówka.
#! /usr/bin/env perl
use Modern::Perl;
# which is the same as these three lines:
# use 5.10.0;
# use strict;
# use warnings;
while( <> ){
chomp;
last unless $_;
Collatz( $_ );
}
Prosta wersja rekurencyjna
use Sub::Call::Recur;
sub Collatz{
my( $n ) = @_;
$n += 0; # ensure that it is numeric
die 'invalid value' unless $n > 0;
die 'Integer values only' unless $n == int $n;
say $n;
given( $n ){
when( 1 ){}
when( $_ % 2 != 0 ){ # odd
recur( 3 * $n + 1 );
}
default{ # even
recur( $n / 2 );
}
}
}
Prosta wersja iteracyjna
sub Collatz{
my( $n ) = @_;
$n += 0; # ensure that it is numeric
die 'invalid value' unless $n > 0;
die 'Integer values only' unless $n == int $n;
say $n;
while( $n > 1 ){
if( $n % 2 ){ # odd
$n = 3 * $n + 1;
} else { #even
$n = $n / 2;
}
say $n;
}
}
Zoptymalizowana wersja iteracyjna
sub Collatz{
my( $n ) = @_;
$n += 0; # ensure that it is numeric
die 'invalid value' unless $n > 0;
die 'Integer values only' unless $n == int $n;
#
state @next;
$next[1] //= 0; # sets $next[1] to 0 if it is undefined
#
# fill out @next until we get to a value we've already worked on
until( defined $next[$n] ){
say $n;
#
if( $n % 2 ){ # odd
$next[$n] = 3 * $n + 1;
} else { # even
$next[$n] = $n / 2;
}
#
$n = $next[$n];
}
say $n;
# finish running until we get to 1
say $n while $n = $next[$n];
}
Teraz pokażę, jak można zrobić ten ostatni przykład z wersją Perla wcześniejszą niż 5.10.0
#! /usr/bin/env perl
use strict;
use warnings;
while( <> ){
chomp;
last unless $_;
Collatz( $_ );
}
{
my @next = (0,0); # essentially the same as a state variable
sub Collatz{
my( $n ) = @_;
$n += 0; # ensure that it is numeric
die 'invalid value' unless $n > 0;
# fill out @next until we get to a value we've already worked on
until( $n == 1 or defined $next[$n] ){
print $n, "\n";
if( $n % 2 ){ # odd
$next[$n] = 3 * $n + 1;
} else { # even
$next[$n] = $n / 2;
}
$n = $next[$n];
}
print $n, "\n";
# finish running until we get to 1
print $n, "\n" while $n = $next[$n];
}
}
Reper
Po pierwsze, IO zawsze będzie wolną częścią. Więc jeśli faktycznie przetestowałeś je w stanie, w jakim są, powinieneś uzyskać mniej więcej taką samą prędkość z każdego z nich.
Aby to przetestować, otworzyłem uchwyt pliku do /dev/null( $null) i edytowałem wszystkie, say $naby zamiast tego czytać say {$null} $n. Ma to na celu zmniejszenie zależności od IO.
#! /usr/bin/env perl
use Modern::Perl;
use autodie;
open our $null, '>', '/dev/null';
use Benchmark qw':all';
cmpthese( -10,
{
Recursive => sub{ Collatz_r( 31 ) },
Iterative => sub{ Collatz_i( 31 ) },
Optimized => sub{ Collatz_o( 31 ) },
});
sub Collatz_r{
...
say {$null} $n;
...
}
sub Collatz_i{
...
say {$null} $n;
...
}
sub Collatz_o{
...
say {$null} $n;
...
}
Po uruchomieniu go 10 razy, oto reprezentatywne przykładowe wyjście:
Oceń cyklicznie iteracyjne zoptymalizowane
Rekursywne 1715 / s - -27% -46%
Iteracyjne 2336 / s 36% - -27%
Zoptymalizowany 3187 / s 86% 36% -
Na koniec prawdziwy wpis dotyczący golfa w kodowaniu:
perl -nlE'say;say$_=$_%2?3*$_+1:$_/2while$_>1'
Łącznie 46 znaków
Jeśli nie musisz drukować wartości początkowej, możesz usunąć 5 dodatkowych znaków.
perl -nE'say$_=$_%2?3*$_+1:$_/2while$_>1'
41 znaków łącznie
31 znaków dla rzeczywistej części kodu, ale kod nie będzie działał bez -nprzełącznika. Więc uwzględniam cały przykład w mojej liczbie.