SQL Server: ustaw wszystkie wielkie litery na odpowiednią wielkość liter / tytuł

Mam tabelę, która została zaimportowana jako wszystkie WIELKIE LITERY i chciałbym zmienić ją na właściwą wielkość. Jakiego skryptu użyliście do wykonania tego zadania?

Oto UDF, który załatwi sprawę ...

create function ProperCase(@Text as varchar(8000))
returns varchar(8000)
as
begin
  declare @Reset bit;
  declare @Ret varchar(8000);
  declare @i int;
  declare @c char(1);

  if @Text is null
    return null;

  select @Reset = 1, @i = 1, @Ret = '';

  while (@i <= len(@Text))
    select @c = substring(@Text, @i, 1),
      @Ret = @Ret + case when @Reset = 1 then UPPER(@c) else LOWER(@c) end,
      @Reset = case when @c like '[a-zA-Z]' then 0 else 1 end,
      @i = @i + 1
  return @Ret
end

Jednak nadal będziesz musiał go używać do aktualizacji danych.

Ta funkcja:

• „Właściwe przypadki” wszystkie słowa z „WIELKIMI LITERAMI”, które są rozdzielane spacjami
• pozostawia same „małe litery”
• działa poprawnie nawet dla alfabetów innych niż angielski
• jest przenośny, ponieważ nie wykorzystuje wymyślnych funkcji najnowszych wersji serwera SQL
• można łatwo zmienić, aby używać NCHAR i NVARCHAR do obsługi Unicode, a także dowolnej długości parametru, którą uznasz za stosowną
• można skonfigurować definicję białych znaków

CREATE FUNCTION ToProperCase(@string VARCHAR(255)) RETURNS VARCHAR(255)
AS
BEGIN
  DECLARE @i INT           -- index
  DECLARE @l INT           -- input length
  DECLARE @c NCHAR(1)      -- current char
  DECLARE @f INT           -- first letter flag (1/0)
  DECLARE @o VARCHAR(255)  -- output string
  DECLARE @w VARCHAR(10)   -- characters considered as white space

  SET @w = '[' + CHAR(13) + CHAR(10) + CHAR(9) + CHAR(160) + ' ' + ']'
  SET @i = 1
  SET @l = LEN(@string)
  SET @f = 1
  SET @o = ''

  WHILE @i <= @l
  BEGIN
    SET @c = SUBSTRING(@string, @i, 1)
    IF @f = 1 
    BEGIN
     SET @o = @o + @c
     SET @f = 0
    END
    ELSE
    BEGIN
     SET @o = @o + LOWER(@c)
    END

    IF @c LIKE @w SET @f = 1

    SET @i = @i + 1
  END

  RETURN @o
END

Wynik:

dbo.ToProperCase('ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')
-----------------------------------------------------------------
All Upper Case and      Some lower Ää Öö Üü Éé Øø Cc Ææ

UPDATE titles
  SET title =
      UPPER(LEFT(title, 1)) +
        LOWER(RIGHT(title, LEN(title) - 1))

http://sqlmag.com/t-sql/how-title-case-column-value

Jeśli możesz włączyć CLR w SQL Server (wymaga wersji 2005 lub nowszej), możesz utworzyć funkcję CLR, która używa wbudowanej funkcji TextInfo.ToTitleCase, która pozwoli ci stworzyć kulturowy sposób zrobienia tego tylko w kilku linie kodu.

Wiem, że to późny post w tym wątku, ale warto go obejrzeć. Ta funkcja działa dla mnie zawsze. Więc pomyślałem o udostępnieniu tego.

CREATE FUNCTION [dbo].[fnConvert_TitleCase] (@InputString VARCHAR(4000) )
RETURNS VARCHAR(4000)
AS
BEGIN
DECLARE @Index INT
DECLARE @Char CHAR(1)
DECLARE @OutputString VARCHAR(255)

SET @OutputString = LOWER(@InputString)
SET @Index = 2
SET @OutputString = STUFF(@OutputString, 1, 1,UPPER(SUBSTRING(@InputString,1,1)))

WHILE @Index <= LEN(@InputString)
BEGIN
    SET @Char = SUBSTRING(@InputString, @Index, 1)
    IF @Char IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&','''','(')
    IF @Index + 1 <= LEN(@InputString)
BEGIN
    IF @Char != ''''
    OR
    UPPER(SUBSTRING(@InputString, @Index + 1, 1)) != 'S'
    SET @OutputString =
    STUFF(@OutputString, @Index + 1, 1,UPPER(SUBSTRING(@InputString, @Index + 1, 1)))
END
    SET @Index = @Index + 1
END

RETURN ISNULL(@OutputString,'')
END

Połączenia testowe:

select dbo.fnConvert_TitleCase(Upper('ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')) as test
select dbo.fnConvert_TitleCase(upper('Whatever the mind of man can conceive and believe, it can achieve. – Napoleon hill')) as test

Wyniki:

Jestem trochę spóźniony w grze, ale wydaje mi się, że jest to bardziej funkcjonalne i działa z każdym językiem, w tym rosyjskim, niemieckim, tajskim, wietnamskim itp. Po „lub - lub” będą wielkie litery. lub (lub) lub spacja (oczywiście :).

CREATE FUNCTION [dbo].[fnToProperCase]( @name nvarchar(500) )
RETURNS nvarchar(500)
AS
BEGIN
declare @pos    int = 1
      , @pos2   int

if (@name <> '')--or @name = lower(@name) collate SQL_Latin1_General_CP1_CS_AS or @name = upper(@name) collate SQL_Latin1_General_CP1_CS_AS)
begin
    set @name = lower(rtrim(@name))
    while (1 = 1)
    begin
        set @name = stuff(@name, @pos, 1, upper(substring(@name, @pos, 1)))
        set @pos2 = patindex('%[- ''.)(]%', substring(@name, @pos, 500))
        set @pos += @pos2
        if (isnull(@pos2, 0) = 0 or @pos > len(@name))
            break
    end
end

return @name
END
GO

Jeśli jesteś w SSIS importującym dane, które mają mieszane wielkości liter i musisz przeprowadzić wyszukiwanie w kolumnie z odpowiednią wielkością liter, zauważysz, że wyszukiwanie nie powiedzie się, gdy źródło jest mieszane, a źródło wyszukiwania jest prawidłowe. Zauważysz również, że nie możesz użyć prawej i lewej funkcji SSIS dla SQL Server 2008r2 dla kolumn pochodnych. Oto rozwiązanie, które działa dla mnie:

UPPER(substring(input_column_name,1,1)) + LOWER(substring(input_column_name, 2, len(input_column_name)-1))

Oto wersja, która używa tabeli sekwencji lub liczb zamiast pętli. Możesz zmodyfikować klauzulę WHERE, aby dostosować ją do własnych zasad dotyczących zmiany znaku na duże litery. Właśnie dołączyłem prosty zestaw, który będzie składał się z wielkich liter każdej litery poprzedzonej literą niebędącą literą, z wyjątkiem apostrofów. To jednak zawsze oznacza, że ​​123apple miałoby dopasowanie na „a”, ponieważ „3” nie jest literą. Jeśli chcesz tylko white-space (przestrzeń, kartę, powrotu karetki, line-feed), można zastąpić wzór '[^a-z]'z '[' + Char(32) + Char(9) + Char(13) + Char(10) + ']'.

CREATE FUNCTION String.InitCap( @string nvarchar(4000) ) RETURNS nvarchar(4000) AS
BEGIN

-- 1. Convert all letters to lower case
    DECLARE @InitCap nvarchar(4000); SET @InitCap = Lower(@string);

-- 2. Using a Sequence, replace the letters that should be upper case with their upper case version
    SELECT @InitCap = Stuff( @InitCap, n, 1, Upper( SubString( @InitCap, n, 1 ) ) )
    FROM (
        SELECT (1 + n1.n + n10.n + n100.n + n1000.n) AS n
        FROM       (SELECT 0 AS n UNION SELECT    1 UNION SELECT    2 UNION SELECT    3 UNION SELECT    4 UNION SELECT    5 UNION SELECT    6 UNION SELECT    7 UNION SELECT    8 UNION SELECT    9) AS    n1
        CROSS JOIN (SELECT 0 AS n UNION SELECT   10 UNION SELECT   20 UNION SELECT   30 UNION SELECT   40 UNION SELECT   50 UNION SELECT   60 UNION SELECT   70 UNION SELECT   80 UNION SELECT   90) AS   n10
        CROSS JOIN (SELECT 0 AS n UNION SELECT  100 UNION SELECT  200 UNION SELECT  300 UNION SELECT  400 UNION SELECT  500 UNION SELECT  600 UNION SELECT  700 UNION SELECT  800 UNION SELECT  900) AS  n100
        CROSS JOIN (SELECT 0 AS n UNION SELECT 1000 UNION SELECT 2000 UNION SELECT 3000)                                                                                                             AS n1000
        ) AS Sequence
    WHERE 
        n BETWEEN 1 AND Len( @InitCap )
    AND SubString( @InitCap, n, 1 ) LIKE '[a-z]'                 /* this character is a letter */
    AND (
        n = 1                                                    /* this character is the first `character` */
        OR SubString( @InitCap, n-1, 1 ) LIKE '[^a-z]'           /* the previous character is NOT a letter */
        )
    AND (
        n < 3                                                    /* only test the 3rd or greater characters for this exception */
        OR SubString( @InitCap, n-2, 3 ) NOT LIKE '[a-z]''[a-z]' /* exception: The pattern <letter>'<letter> should not capatolize the letter following the apostrophy */
        )

-- 3. Return the modified version of the input
    RETURN @InitCap

END

Link, który zamieściłem powyżej, to świetna opcja, która rozwiązuje główny problem: że nigdy nie możemy programowo wyjaśnić wszystkich przypadków (Smith-Jones, von Haussen, John Smith MD), przynajmniej nie w elegancki sposób. Tony wprowadza koncepcję znaku wyjątku / przerwy, aby poradzić sobie z takimi przypadkami. W każdym razie, opierając się na pomyśle Cervo (górne wszystkie dolne znaki poprzedzone spacją), instrukcje zamiany mogłyby być opakowane w jedną tabelę opartą na zamianie. Naprawdę, do @alpha można wstawić dowolną kombinację znaków dolnych / górnych, a instrukcja się nie zmieni:

declare @str    nvarchar(8000)
declare @alpha  table (low nchar(1), up nchar(1))


set @str = 'ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ'

-- stage the alpha (needs number table)
insert into @alpha
    -- A-Z / a-z
    select      nchar(n+32),
                nchar(n)
    from        dbo.Number
    where       n between 65 and 90 or
                n between 192 and 223

-- append space at start of str
set @str = lower(' ' + @str)

-- upper all lower case chars preceded by space
select  @str = replace(@str, ' ' + low, ' ' + up) 
from    @Alpha

select @str

Miałoby sens utrzymywanie wyszukiwania wyjątków, aby zająć się The von Neumann's, McCain's, DeGuzman's i the Johnson-Smith's.

Pożyczone i poprawione w odpowiedzi @Richard Sayakanit. Obsługuje wiele słów. Podobnie jak jego odpowiedź, nie używa żadnych UDF, tylko wbudowane funkcje ( STRING_SPLITi STRING_AGG) i jest dość szybkie. STRING_AGGwymaga SQL Server 2017, ale zawsze możesz użyć STUFF/XMLsztuczki. Nie poradzi sobie z każdym wyjątkiem, ale może się świetnie sprawdzić w wielu sytuacjach.

SELECT StateName = 'North Carolina' 
INTO #States
UNION ALL
SELECT 'Texas'


;WITH cteData AS 
(
    SELECT 
        UPPER(LEFT(value, 1)) +
            LOWER(RIGHT(value, LEN(value) - 1)) value, op.StateName
    FROM   #States op
    CROSS APPLY STRING_SPLIT(op.StateName, ' ') AS ss
)
SELECT 
    STRING_AGG(value, ' ')
FROM cteData c 
GROUP BY StateName

Niewielkie modyfikacje @ odpowiedź Galwegian - który zakręty np St Elizabeth'sdo St Elizabeth'S.

Ta modyfikacja zachowuje apostrofy-s jako małe litery, gdy s występuje na końcu podanego ciągu lub po s następuje spacja (i tylko w takich okolicznościach).

create function properCase(@text as varchar(8000))
returns varchar(8000)
as
begin
    declare @reset int;
    declare @ret varchar(8000);
    declare @i int;
    declare @c char(1);
    declare @d char(1);

    if @text is null
    return null;

    select @reset = 1, @i = 1, @ret = '';

    while (@i <= len(@text))
    select
        @c = substring(@text, @i, 1),
        @d = substring(@text, @i+1, 1),
        @ret = @ret + case when @reset = 1 or (@reset=-1 and @c!='s') or (@reset=-1 and @c='s' and @d!=' ') then upper(@c) else lower(@c) end,
        @reset = case when @c like '[a-za-z]' then 0 when @c='''' then -1 else 1 end,
        @i = @i + 1
    return @ret
end

Skręca, zakręca:

• st elizabeth's w St Elizabeth's
• o'keefe w O'Keefe
• o'sullivan w O'Sullivan

Komentarze innych, że inne rozwiązania są lepsze w przypadku wprowadzania tekstu w języku innym niż angielski, pozostają aktualne.

Myślę, że przekonasz się, że bardziej wydajne są:

IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
    DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
    @str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    SET @str = ' ' + @str
    SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE( @str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z')
    RETURN RIGHT(@str, LEN(@str) - 1)
END
GO

Instrukcja replace można wyciąć i wkleić bezpośrednio do zapytania SQL. Jest to bardzo brzydkie, jednak zastępując @str kolumną, którą jesteś zainteresowany, nie zapłacisz ceny za domyślny kursor, tak jak w przypadku opublikowanego w ten sposób udfs. Uważam, że nawet używanie mojego UDF jest znacznie wydajniejsze.

Aha i zamiast ręcznie generować instrukcję zamiany, użyj tego:

-- Code Generator for expression
DECLARE @x  INT,
    @c  CHAR(1),
    @sql    VARCHAR(8000)
SET @x = 0
SET @sql = '@str' -- actual variable/column you want to replace
WHILE @x < 26
BEGIN
    SET @c = CHAR(ASCII('a') + @x)
    SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+  ''', '' ' + UPPER(@c) + ''')'
    SET @x = @x + 1
END
PRINT @sql

W każdym razie zależy to od liczby rzędów. Chciałbym, żebyś mógł zrobić s / \ b ([az]) / uc $ 1 /, ale cóż, pracujemy z narzędziami, które mamy.

UWAGA, musiałbyś użyć tego tak, jakbyś musiał użyć go jako .... SELECT dbo.ProperCase (LOWER (kolumna)), ponieważ kolumna jest zapisana wielkimi literami. W rzeczywistości działa dość szybko na mojej tabeli zawierającej 5000 wpisów (nie ma nawet jednej sekundy), nawet z niższymi.

W odpowiedzi na lawinę komentarzy dotyczących internacjonalizacji przedstawiam następującą implementację, która obsługuje każdy znak ascii, opierając się wyłącznie na implementacji wyższego i niższego języka SQL Server. Pamiętaj, zmienne, których tutaj używamy, to VARCHAR, co oznacza, że ​​mogą przechowywać tylko wartości ASCII. Aby używać kolejnych międzynarodowych alfabetów, musisz użyć NVARCHAR. Logika byłaby podobna, ale musiałbyś użyć UNICODE i NCHAR zamiast ASCII I CHAR, a instrukcja zamiany byłaby znacznie większa ....

-- Code Generator for expression
DECLARE @x  INT,
    @c  CHAR(1),
    @sql    VARCHAR(8000),
    @count  INT
SEt @x = 0
SET @count = 0
SET @sql = '@str' -- actual variable you want to replace
WHILE @x < 256
BEGIN
    SET @c = CHAR(@x)
    -- Only generate replacement expression for characters where upper and lowercase differ
    IF @x = ASCII(LOWER(@c)) AND @x != ASCII(UPPER(@c))
    BEGIN
        SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+  ''', '' ' + UPPER(@c) + ''')'
        SET @count = @count + 1
    END
    SET @x = @x + 1
END
PRINT @sql
PRINT 'Total characters substituted: ' + CONVERT(VARCHAR(255), @count)

Zasadniczo założeniem mojej metody jest zamiana wydajności obliczeń wstępnych. Pełna implementacja ASCII jest następująca:

IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
    DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
    @str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    SET @str = ' ' + @str
SET @str =     REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(@str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z'), ' š', ' Š'), ' œ', ' Œ'), ' ž', ' Ž'), ' à', ' À'), ' á', ' Á'), ' â', ' Â'), ' ã', ' Ã'), ' ä', ' Ä'), ' å', ' Å'), ' æ', ' Æ'), ' ç', ' Ç'), ' è', ' È'), ' é', ' É'), ' ê', ' Ê'), ' ë', ' Ë'), ' ì', ' Ì'), ' í', ' Í'), ' î', ' Î'), ' ï', ' Ï'), ' ð', ' Ð'), ' ñ', ' Ñ'), ' ò', ' Ò'), ' ó', ' Ó'), ' ô', ' Ô'), ' õ', ' Õ'), ' ö', ' Ö'), ' ø', ' Ø'), ' ù', ' Ù'), ' ú', ' Ú'), ' û', ' Û'), ' ü', ' Ü'), ' ý', ' Ý'), ' þ', ' Þ'), ' ÿ', ' Ÿ')
    RETURN RIGHT(@str, LEN(@str) - 1)
END
GO

Czy jest już za późno, aby wrócić i uzyskać dane bez dużych liter?

Von Neumanna, McCaina, DeGuzmana i Johnsona-Smitha z bazy klientów mogą nie lubić wyniku przetwarzania ...

Zgaduję też, że ma to być jednorazowa aktualizacja danych? Może być łatwiej eksportować, filtrować / modyfikować i ponownie importować poprawione nazwy do bazy danych, a wtedy można użyć metod innych niż SQL do poprawiania nazw ...

Oto kolejna odmiana, którą znalazłem na forach SQLTeam.com @ http://www.sqlteam.com/forums/topic.asp?TOPIC_ID=47718

create FUNCTION PROPERCASE
(
--The string to be converted to proper case
@input varchar(8000)
)
--This function returns the proper case string of varchar type
RETURNS varchar(8000)
AS
BEGIN
IF @input IS NULL
BEGIN
--Just return NULL if input string is NULL
RETURN NULL
END

--Character variable declarations
DECLARE @output varchar(8000)
--Integer variable declarations
DECLARE @ctr int, @len int, @found_at int
--Constant declarations
DECLARE @LOWER_CASE_a int, @LOWER_CASE_z int, @Delimiter char(3), @UPPER_CASE_A int, @UPPER_CASE_Z int

--Variable/Constant initializations
SET @ctr = 1
SET @len = LEN(@input)
SET @output = ''
SET @LOWER_CASE_a = 97
SET @LOWER_CASE_z = 122
SET @Delimiter = ' ,-'
SET @UPPER_CASE_A = 65
SET @UPPER_CASE_Z = 90

WHILE @ctr <= @len
BEGIN
--This loop will take care of reccuring white spaces
WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) > 0
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
SET @ctr = @ctr + 1
END

IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @LOWER_CASE_a AND @LOWER_CASE_z
BEGIN
--Converting the first character to upper case
SET @output = @output + UPPER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END

SET @ctr = @ctr + 1

WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) = 0 AND (@ctr <= @len)
BEGIN
IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @UPPER_CASE_A AND @UPPER_CASE_Z
BEGIN
SET @output = @output + LOWER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END
SET @ctr = @ctr + 1
END

END
RETURN @output
END



GO
SET QUOTED_IDENTIFIER OFF
GO
SET ANSI_NULLS ON
GO

Wiem, że diabeł tkwi w szczegółach (szczególnie jeśli chodzi o dane osobowe ludzi) i że byłoby bardzo miło mieć imiona pisane wielką literą, ale powyższy rodzaj kłopotów jest powodem, dla którego pragmatyczni, świadomi czasu wśród nas używają następującego :

SELECT UPPER('Put YoUR O'So oddLy casED McWeird-nAme von rightHERE here')

Z mojego doświadczenia wynika, że ​​ludzie dobrze widzą ICH NAZWISKO ... nawet w połowie zdania.

Zobacz: Rosjanie używali ołówka!

Właśnie dowiedziałem się o InitCap().

Oto przykładowy kod:

SELECT ID
      ,InitCap(LastName ||', '|| FirstName ||' '|| Nvl(MiddleName,'')) AS RecipientName
FROM SomeTable

To działało w SSMS:

Select Jobtitle,
concat(Upper(LEFT(jobtitle,1)), SUBSTRING(jobtitle,2,LEN(jobtitle))) as Propercase
From [HumanResources].[Employee]

Jeśli wiesz, że wszystkie dane to tylko jedno słowo, oto rozwiązanie. Najpierw zaktualizuj kolumnę do wszystkich niższych, a następnie uruchom następujące

    update tableName set columnName = 
    upper(SUBSTRING(columnName, 1, 1)) + substring(columnName, 2, len(columnName)) from tableName

Niedawno musiałem sobie z tym poradzić i wymyśliłem następujące, po tym, jak nic nie trafiło we wszystko, czego chciałem. Spowoduje to wykonanie całego zdania, przypadków do specjalnej obsługi słów. Mieliśmy również problemy z jednoznakowymi „słowami”, które obsługuje wiele prostszych metod, ale nie metody bardziej skomplikowane. Pojedyncza zmienna zwrotna, bez pętli ani kursorów.

CREATE FUNCTION ProperCase(@Text AS NVARCHAR(MAX))
RETURNS NVARCHAR(MAX)
AS BEGIN

    DECLARE @return NVARCHAR(MAX)

    SELECT @return = COALESCE(@return + ' ', '') + Word FROM (
         SELECT CASE
            WHEN LOWER(value) = 'llc' THEN UPPER(value)
            WHEN LOWER(value) = 'lp' THEN UPPER(value) --Add as many new special cases as needed
            ELSE
               CASE WHEN LEN(value) = 1
               THEN UPPER(value)
               ELSE UPPER(LEFT(value, 1)) + (LOWER(RIGHT(value, LEN(value) - 1)))
              END
            END AS Word
         FROM STRING_SPLIT(@Text, ' ')
     ) tmp

     RETURN @return
END

Skopiuj i wklej swoje dane do MS Word i użyj wbudowanej konwersji tekstu, aby „używać wielkich liter w każdym słowie”. Porównaj z oryginalnymi danymi, aby uwzględnić wyjątki. Nie widzę żadnego sposobu na ręczne ominięcie wyjątków typu „MacDonald” i „IBM”, ale w ten sposób wykonałem to FWIW.

Na serwerze Server 2016 i nowszych możesz użyć STRING_SPLIT

with t as (
    select 'GOOFYEAR Tire and Rubber Company' as n
    union all
    select 'THE HAPPY BEAR' as n
    union all
    select 'MONK HOUSE SALES' as n
    union all
    select 'FORUM COMMUNICATIONS' as n
)
select
    n,
    (
        select ' ' + (
            upper(left(value, 1))
            + lower(substring(value, 2, 999))
        )
        from (
            select value
            from string_split(t.n, ' ')
        ) as sq
        for xml path ('')
    ) as title_cased
from t

Przykład