Rozwiąż ścieżkę bezwzględną na podstawie ścieżki względnej i / lub nazwy pliku

Czy istnieje sposób w skrypcie wsadowym systemu Windows, aby zwrócić ścieżkę bezwzględną z wartości zawierającej nazwę pliku i / lub ścieżkę względną?

Dany:

"..\"
"..\somefile.txt"

Potrzebuję bezwzględnej ścieżki względem pliku wsadowego.

Przykład:

• Plik „somefile.txt” znajduje się w „C: \ Foo \”
• „test.bat” znajduje się w „C: \ Foo \ Bar”.
• Użytkownik otwiera okno poleceń w „C: \ Foo” i wywołuje Bar\test.bat ..\somefile.txt
• W pliku wsadowym będzie pochodzić „C: \ Foo \ somefile.txt” %1

W plikach wsadowych, podobnie jak w standardowych programach C, argument 0 zawiera ścieżkę do aktualnie wykonywanego skryptu. Możesz użyć, %~dp0aby uzyskać tylko część ścieżki zerowego argumentu (który jest bieżącym skryptem) - ta ścieżka jest zawsze w pełni kwalifikowaną ścieżką.

Możesz również uzyskać w pełni kwalifikowaną ścieżkę pierwszego argumentu, używając %~f1, ale daje to ścieżkę zgodnie z bieżącym katalogiem roboczym, co oczywiście nie jest tym, czego chcesz.

Osobiście często używam %~dp0%~1idiomu w moim pliku wsadowym, który interpretuje pierwszy argument w stosunku do ścieżki wykonującej partii. Ma jednak wadę: nieszczęśliwie zawodzi, jeśli pierwszy argument jest w pełni kwalifikowany.

Jeśli potrzebujesz obsługiwać zarówno ścieżki względne, jak i bezwzględne, możesz skorzystać z rozwiązania Frédéric Ménez : tymczasowo zmień bieżący katalog roboczy.

Oto przykład, który zademonstruje każdą z tych technik:

@echo off
echo %%~dp0 is "%~dp0"
echo %%0 is "%0"
echo %%~dpnx0 is "%~dpnx0"
echo %%~f1 is "%~f1"
echo %%~dp0%%~1 is "%~dp0%~1"

rem Temporarily change the current working directory, to retrieve a full path 
rem   to the first parameter
pushd .
cd %~dp0
echo batch-relative %%~f1 is "%~f1"
popd

Jeśli zapiszesz to jako c: \ temp \ example.bat i uruchomisz go z c: \ Users \ Public jako

c: \ Users \ Public> \ temp \ example.bat .. \ windows

... zobaczysz następujący wynik:

%~dp0 is "C:\temp\"
%0 is "\temp\example.bat"
%~dpnx0 is "C:\temp\example.bat"
%~f1 is "C:\Users\windows"
%~dp0%~1 is "C:\temp\..\windows"
batch-relative %~f1 is "C:\Windows"

dokumentację dotyczącą zestawu modyfikatorów dozwolonych w argumencie wsadowym można znaleźć tutaj: https://docs.microsoft.com/en-us/windows-server/administration/windows-commands/call

Dziś rano spotkałem się z podobną potrzebą: jak przekonwertować ścieżkę względną na ścieżkę bezwzględną w skrypcie poleceń systemu Windows.

Oto co załatwiło sprawę:

@echo off

set REL_PATH=..\..\
set ABS_PATH=

rem // Save current directory and change to target directory
pushd %REL_PATH%

rem // Save value of CD variable (current directory)
set ABS_PATH=%CD%

rem // Restore original directory
popd

echo Relative path: %REL_PATH%
echo Maps to path: %ABS_PATH%

Większość z tych odpowiedzi wydaje się szalona przez skomplikowane i bardzo błędne, oto moje - działa na każdej zmiennej środowiskowej, bez %CD%lub PUSHD/ POPDlub for /fnonsensem - po prostu zwykłe stare funkcje wsadowe. - Katalog i plik nie muszą nawet istnieć.

CALL :NORMALIZEPATH "..\..\..\foo\bar.txt"
SET BLAH=%RETVAL%

ECHO "%BLAH%"

:: ========== FUNCTIONS ==========
EXIT /B

:NORMALIZEPATH
  SET RETVAL=%~dpfn1
  EXIT /B

Bez konieczności posiadania innego pliku wsadowego do przekazywania argumentów (i używania operatorów argumentów), możesz użyć FOR /F:

FOR /F %%i IN ("..\relativePath") DO echo absolute path: %%~fi

gdzie iin %%~fijest zmienną zdefiniowaną w /F %%i. na przykład. gdybyś to zmienił, /F %%ato ostatnia część byłaby %%~fa.

Aby zrobić to samo słuszne w wierszu poleceń (a nie w pliku wsadowym) zastąpić %%z %...

Ma to pomóc wypełnić luki w odpowiedzi Adriena Plissona (którą należy zaopiniować, gdy tylko ją zredaguje ;-):

możesz również uzyskać pełną ścieżkę swojego pierwszego argumentu używając% ~ f1, ale daje to ścieżkę zgodną z bieżącą ścieżką, co oczywiście nie jest tym, czego chcesz.

niestety nie wiem, jak połączyć te 2 razem ...

Można sobie z tym poradzić %0i %1podobnie:

• %~dpnx0dla w pełni kwalifikowanego dysku + ścieżka + nazwa + rozszerzenie samego pliku wsadowego,
  %~f0również wystarczy;
• %~dpnx1dla w pełni kwalifikowanego dysku + ścieżka + nazwa + rozszerzenie pierwszego argumentu [jeśli w ogóle jest to nazwa pliku],
  %~f1również wystarcza;

%~f1będzie działać niezależnie od tego, jak podałeś swój pierwszy argument: ze ścieżkami względnymi lub ścieżkami bezwzględnymi (jeśli nie określisz rozszerzenia pliku podczas nadawania nazwy %1, nie zostanie on dodany, nawet jeśli użyjesz %~dpnx1- jednak.

Ale jak, u licha, nazwałbyś plik na innym dysku , gdybyś nie podał tej pełnej informacji o ścieżce w linii poleceń?

Jednak %~p0, %~n0, %~nx0i %~x0może się przydać, powinien być zainteresowany w ścieżce (bez litera_dysku), nazwę pliku (bez rozszerzenia), pełną nazwę pliku z rozszerzeniem lub tylko rozszerzenie pliku jest. Ale zwróć uwagę, że while %~p1i %~n1będzie działać, aby znaleźć ścieżkę lub nazwę pierwszego argumentu, %~nx1i %~x1nie doda + pokaż rozszerzenia, chyba że użyłeś go już w linii poleceń.

Możesz również użyć do tego funkcji wsadowych:

@echo off
setlocal 

goto MAIN
::-----------------------------------------------
:: "%~f2" get abs path of %~2. 
::"%~fs2" get abs path with short names of %~2.
:setAbsPath
  setlocal
  set __absPath=%~f2
  endlocal && set %1=%__absPath%
  goto :eof
::-----------------------------------------------

:MAIN
call :setAbsPath ABS_PATH ..\
echo %ABS_PATH%

endlocal

Małe ulepszenie doskonałego rozwiązania BrainSlugs83 . Uogólnione, aby umożliwić nazwanie wyjściowej zmiennej środowiskowej w wywołaniu.

@echo off
setlocal EnableDelayedExpansion

rem Example input value.
set RelativePath=doc\build

rem Resolve path.
call :ResolvePath AbsolutePath %RelativePath%

rem Output result.
echo %AbsolutePath%

rem End.
exit /b

rem === Functions ===

rem Resolve path to absolute.
rem Param 1: Name of output variable.
rem Param 2: Path to resolve.
rem Return: Resolved absolute path.
:ResolvePath
    set %1=%~dpfn2
    exit /b

Jeśli uruchomienie z C:\projectwyjścia to:

C:\project\doc\build

Nie widziałem wielu rozwiązań tego problemu. Niektóre rozwiązania wykorzystują przemierzanie katalogów za pomocą CD, a inne wykorzystują funkcje wsadowe. Osobiście preferowałem funkcje wsadowe, aw szczególności funkcję MakeAbsolute dostarczaną przez DosTips.

Ta funkcja ma pewne realne korzyści, przede wszystkim to, że nie zmienia bieżącego katalogu roboczego, a po drugie, oceniane ścieżki nie muszą nawet istnieć. Można znaleźć kilka pomocnych wskazówek, jak korzystać z funkcji tutaj też.

Oto przykładowy skrypt i jego wyniki:

@echo off

set scriptpath=%~dp0
set siblingfile=sibling.bat
set siblingfolder=sibling\
set fnwsfolder=folder name with spaces\
set descendantfolder=sibling\descendant\
set ancestorfolder=..\..\
set cousinfolder=..\uncle\cousin

call:MakeAbsolute siblingfile      "%scriptpath%"
call:MakeAbsolute siblingfolder    "%scriptpath%"
call:MakeAbsolute fnwsfolder       "%scriptpath%"
call:MakeAbsolute descendantfolder "%scriptpath%"
call:MakeAbsolute ancestorfolder   "%scriptpath%"
call:MakeAbsolute cousinfolder     "%scriptpath%"

echo scriptpath:       %scriptpath%
echo siblingfile:      %siblingfile%
echo siblingfolder:    %siblingfolder%
echo fnwsfolder:       %fnwsfolder%
echo descendantfolder: %descendantfolder%
echo ancestorfolder:   %ancestorfolder%
echo cousinfolder:     %cousinfolder%
GOTO:EOF

::----------------------------------------------------------------------------------
:: Function declarations
:: Handy to read http://www.dostips.com/DtTutoFunctions.php for how dos functions
:: work.
::----------------------------------------------------------------------------------
:MakeAbsolute file base -- makes a file name absolute considering a base path
::                      -- file [in,out] - variable with file name to be converted, or file name itself for result in stdout
::                      -- base [in,opt] - base path, leave blank for current directory
:$created 20060101 :$changed 20080219 :$categories Path
:$source http://www.dostips.com
SETLOCAL ENABLEDELAYEDEXPANSION
set "src=%~1"
if defined %1 set "src=!%~1!"
set "bas=%~2"
if not defined bas set "bas=%cd%"
for /f "tokens=*" %%a in ("%bas%.\%src%") do set "src=%%~fa"
( ENDLOCAL & REM RETURN VALUES
    IF defined %1 (SET %~1=%src%) ELSE ECHO.%src%
)
EXIT /b

A wynik:

C:\Users\dayneo\Documents>myscript
scriptpath:       C:\Users\dayneo\Documents\
siblingfile:      C:\Users\dayneo\Documents\sibling.bat
siblingfolder:    C:\Users\dayneo\Documents\sibling\
fnwsfolder:       C:\Users\dayneo\Documents\folder name with spaces\
descendantfolder: C:\Users\dayneo\Documents\sibling\descendant\
ancestorfolder:   C:\Users\
cousinfolder:     C:\Users\dayneo\uncle\cousin

Mam nadzieję, że to pomoże ... Na pewno mi pomogło :) PS Jeszcze raz dziękuję DosTips! Rządzisz!

Możesz je po prostu połączyć.

SET ABS_PATH=%~dp0 
SET REL_PATH=..\SomeFile.txt
SET COMBINED_PATH=%ABS_PATH%%REL_PATH%

wygląda to dziwnie z \ .. \ na środku ścieżki, ale działa. Nie musisz robić nic szalonego :)

W naszym przykładzie z Bar \ test.bat DIR / B / S .. \ somefile.txt zwróci pełną ścieżkę.

PowerShell jest obecnie dość powszechny, więc często używam go jako szybkiego sposobu wywoływania C #, ponieważ ma on funkcje dla prawie wszystkiego:

@echo off
set pathToResolve=%~dp0\..\SomeFile.txt
for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo Resolved path: %resolvedPath%

Jest trochę powolny, ale uzyskana funkcjonalność jest trudna do pokonania, chyba że bez uciekania się do rzeczywistego języka skryptowego.

rozwiązanie stijn działa z podfolderami pod C:\Program Files (86)\,

@echo off
set projectDirMc=test.txt

for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo full path:    %resolvedPath%

Pliki Zobacz wszystkie inne odpowiedzi

Katalogi

Z ..bycia swoją ścieżką względną, a zakładając, że jesteś obecnie w D:\Projects\EditorProject:

cd .. & cd & cd EditorProject (ścieżka względna)

zwraca ścieżkę bezwzględną np

D:\Projects

SET CD=%~DP0

SET REL_PATH=%CD%..\..\build\

call :ABSOLUTE_PATH    ABS_PATH   %REL_PATH%

ECHO %REL_PATH%

ECHO %ABS_PATH%

pause

exit /b

:ABSOLUTE_PATH

SET %1=%~f2

exit /b