Struktura pętli wewnątrz gnuplot?

Czy istnieje sposób na iteracyjne pobieranie danych z wielu plików i wykreślanie ich na tym samym wykresie w gnuplot? Załóżmy, że mam pliki takie jak data1.txt, data2.txt ...... data1000.txt; każda ma taką samą liczbę kolumn. Teraz mógłbym napisać coś takiego:

plot "data1.txt" using 1:2 title "Flow 1", \
     "data2.txt" using 1:2 title "Flow 2", \
      .
      .
      .
     "data1000.txt"  using 1:2 title "Flow 6"

Ale to byłoby naprawdę niewygodne. Zastanawiałem się, czy istnieje sposób na zapętlenie części fabularnej w gnuplot.

Na pewno jest (w gnuplot 4.4+):

plot for [i=1:1000] 'data'.i.'.txt' using 1:2 title 'Flow '.i

Zmienna imoże być interpretowana jako zmienna lub ciąg, więc możesz zrobić coś takiego

plot for [i=1:1000] 'data'.i.'.txt' using 1:($2+i) title 'Flow '.i

jeśli chcesz, aby linie były odsunięte od siebie.

Wpisz help iterationw wierszu poleceń gnuplot, aby uzyskać więcej informacji.

Koniecznie zobacz również odpowiedź @ DarioP na temat do forskładni; to daje coś bliższego tradycyjnej forpętli.

Spójrz także na do { ... }polecenie od wersji gnuplot 4.6, ponieważ jest bardzo potężne:

do for [t=0:50] {
  outfile = sprintf('animation/bessel%03.0f.png',t)
  set output outfile
  splot u*sin(v),u*cos(v),bessel(u,t/50.0) w pm3d ls 1
}

http://www.gnuplotting.org/gnuplot-4-6-do/

Mam skrypt all.p

set ...
...
list=system('ls -1B *.dat')
plot for [file in list] file w l u 1:2 t file

Tutaj dwa ostatnie wiersze są dosłowne, a nie heurystyczne. Potem biegnę

$ gnuplot -p all.p

Zmień *.datna typ posiadanego pliku lub dodaj typy plików.

Następny krok: Dodaj do ~ / .bashrc tę linię

alias p='gnuplot -p ~/./all.p'

i umieść plik w all.pswoim katalogu domowym i voila. Możesz wydrukować wszystkie pliki w dowolnym katalogu, wpisując p i Enter.

EDYCJA Zmieniłem polecenie, ponieważ nie działa. Wcześniej zawierał list(i)=word(system(ls -1B *.dat),i).

Użyj poniższych, jeśli masz oddzielne kolumny do wykreślenia na wykresie

do for [indx in "2 3 7 8"] {
  column = indx + 0
  plot ifile using 1:column ;  
}

Chciałem użyć symboli wieloznacznych do wykreślenia wielu plików często umieszczanych w różnych katalogach, podczas pracy z dowolnego katalogu. Rozwiązaniem, które znalazłem, było utworzenie następującej funkcji w~/.bashrc

plo () {
local arg="w l"
local str="set term wxt size 900,500 title 'wild plotting'
set format y '%g'
set logs
plot"
while [ $# -gt 0 ]
        do str="$str '$1' $arg,"
        shift
done
echo "$str" | gnuplot -persist
}

i użyj go np. plo *.dat ../../dir2/*.outdo wykreślenia wszystkich .datplików w bieżącym katalogu i wszystkich .outplików w katalogu, który znajduje się na wyższym poziomie i jest nazywany dir2.

Oto alternatywne polecenie:

gnuplot -p -e 'plot for [file in system("find . -name \\*.txt -depth 1")] file using 1:2 title file with lines'