Jak tworzyć i zapisywać w pliku txt za pomocą VBA

Mam plik, który jest ręcznie dodawany lub modyfikowany na podstawie danych wejściowych. Ponieważ większość zawartości w tym pliku jest powtarzalna, zmieniają się tylko wartości szesnastkowe, chcę, aby był to plik wygenerowany przez narzędzie.

Chcę napisać kody c, które zostaną wydrukowane w tym pliku .txt .

Jakie jest polecenie utworzenia pliku .txt za pomocą VBA i jak mam do niego pisać

Aby rozwinąć odpowiedź Bena :

Jeśli dodać odwołanie do Microsoft Scripting Runtimei poprawnie wpisać zmienną FSO można skorzystać z autouzupełniania (Intellisense) i odkryć innych wspaniałych cech FileSystemObject.

Oto kompletny przykładowy moduł:

Option Explicit

' Go to Tools -> References... and check "Microsoft Scripting Runtime" to be able to use
' the FileSystemObject which has many useful features for handling files and folders
Public Sub SaveTextToFile()

    Dim filePath As String
    filePath = "C:\temp\MyTestFile.txt"

    ' The advantage of correctly typing fso as FileSystemObject is to make autocompletion
    ' (Intellisense) work, which helps you avoid typos and lets you discover other useful
    ' methods of the FileSystemObject
    Dim fso As FileSystemObject
    Set fso = New FileSystemObject
    Dim fileStream As TextStream

    ' Here the actual file is created and opened for write access
    Set fileStream = fso.CreateTextFile(filePath)

    ' Write something to the file
    fileStream.WriteLine "something"

    ' Close it, so it is not locked anymore
    fileStream.Close

    ' Here is another great method of the FileSystemObject that checks if a file exists
    If fso.FileExists(filePath) Then
        MsgBox "Yay! The file was created! :D"
    End If

    ' Explicitly setting objects to Nothing should not be necessary in most cases, but if
    ' you're writing macros for Microsoft Access, you may want to uncomment the following
    ' two lines (see https://stackoverflow.com/a/517202/2822719 for details):
    'Set fileStream = Nothing
    'Set fso = Nothing

End Sub

Użyj FSO, aby utworzyć plik i zapisać do niego.

Dim fso as Object
Set fso = CreateObject("Scripting.FileSystemObject")
Dim oFile as Object
Set oFile = FSO.CreateTextFile(strPath)
oFile.WriteLine "test" 
oFile.Close
Set fso = Nothing
Set oFile = Nothing    

Zobacz dokumentację tutaj:

• http://technet.microsoft.com/en-us/library/ee198742.aspx
• http://technet.microsoft.com/en-us/library/ee198716.aspx

Open ThisWorkbook.Path & "\template.txt" For Output As #1
Print #1, strContent
Close #1

Więcej informacji:

• Microsoft Docs: Openoświadczenie
• Microsoft Docs: Print #oświadczenie
• Microsoft Docs: Closeoświadczenie
• wellsr.com: VBA zapisuje do pliku tekstowego za pomocą Printinstrukcji
• Office Support: Workbook.Pathnieruchomość

łatwy sposób bez dużej nadmiarowości.

    Dim fso As Object
    Set fso = CreateObject("Scripting.FileSystemObject")

    Dim Fileout As Object
    Set Fileout = fso.CreateTextFile("C:\your_path\vba.txt", True, True)
    Fileout.Write "your string goes here"
    Fileout.Close

Dim SaveVar As Object

Sub Main()

    Console.WriteLine("Enter Text")

    Console.WriteLine("")

    SaveVar = Console.ReadLine

    My.Computer.FileSystem.WriteAllText("N:\A-Level Computing\2017!\PPE\SaveFile\SaveData.txt", "Text: " & SaveVar & ", ", True)

    Console.WriteLine("")

    Console.WriteLine("File Saved")

    Console.WriteLine("")

    Console.WriteLine(My.Computer.FileSystem.ReadAllText("N:\A-Level Computing\2017!\PPE\SaveFile\SaveData.txt"))
    Console.ReadLine()

End Sub()