Jak określić rozmiar moich tabel w bazie danych SQL Server

Czy jest jakaś wbudowana funkcja / procedura składowana / zapytanie, które są pomocne w celu uzyskania informacji o rozmiarze MyTablew bazie danych SQL Server?

Do pojedynczego stołu możesz użyć

sp_spaceused MyTable

Dla wszystkich tabel w bazie danych możesz używać go sp_msforeachtablejako śledzenia

CREATE TABLE #temp (
table_name sysname ,
row_count INT,
reserved_size VARCHAR(50),
data_size VARCHAR(50),
index_size VARCHAR(50),
unused_size VARCHAR(50))
SET NOCOUNT ON
INSERT #temp
EXEC sp_msforeachtable 'sp_spaceused ''?'''
SELECT a.table_name,
a.row_count,
COUNT(*) AS col_count,
a.data_size
FROM #temp a
INNER JOIN information_schema.columns b
ON a.table_name collate database_default
= b.table_name collate database_default
GROUP BY a.table_name, a.row_count, a.data_size
ORDER BY CAST(REPLACE(a.data_size, ' KB', '') AS integer) DESC
DROP TABLE #temp

Jeśli nie chcesz pisać skryptu, możesz także otworzyć bardzo niewykorzystane „Szczegóły Eksploratora obiektów” w SSMS (klawisz skrótu F7).

Z najwyższego poziomu otwórz folder Tabele, aby uzyskać listę wszystkich tabel w bazie danych.

Konieczne może być dostosowanie kolumn, aby zobaczyć zajęte miejsce. Można to zrobić, klikając prawym przyciskiem myszy wiersz nagłówka i wybierając kolumny, które chcesz wyświetlić.

Jest dużo więcej takich danych dostępnych w Szczegółach Eksploratora obiektów.

W SSMS kliknij prawym przyciskiem myszy Baza danych, wybierz Raporty, Raporty standardowe, Wykorzystanie dysku według najlepszych tabel.

Raport poda liczbę wierszy i kilobajtów używanych na tabelę.

Spójrz na sys.dm_db_partition_stats ( http://msdn.microsoft.com/en-us/library/ms187737.aspx ).

Istnieje kilka przykładowych zapytań pod tym linkiem, a także na stronie http://blogs.msdn.com/b/cindygross/archive/2010/04/02/dmv-series-sys-dm-db-partition-stats.aspx

Możesz modyfikować według własnych potrzeb, np. Filtrować indeksy nieklastrowane. Pomnóż liczbę stron przez 8, aby uzyskać rozmiar w KB, a następnie podziel przez 2 ^ 10 (= 1024), aby w razie potrzeby przekonwertować na MB.

sp_spaceused ( http://msdn.microsoft.com/en-us/library/ms188776.aspx ) poda również informacje o rozmiarze tabeli.

Aby uzyskać informacje o rozmiarze tabeli, lubię użyć następującego skryptu

SELECT  sc.name + '.' + t.NAME AS TableName,  
        p.[Rows],  
        ( SUM(a.total_pages) * 8 ) / 1024 AS TotalReservedSpaceMB, -- Number of total pages * 8KB size of each page in SQL Server  
        ( SUM(a.used_pages) * 8 ) / 1024 AS UsedDataSpaceMB,  
        ( SUM(a.data_pages) * 8 ) / 1024 AS FreeUnusedSpaceMB  
FROM    msdb.sys.tables t  
        INNER JOIN msdb.sys.schemas sc ON sc.schema_id = t.schema_id  
        INNER JOIN msdb.sys.indexes i ON t.OBJECT_ID = i.object_id  
        INNER JOIN msdb.sys.partitions p ON i.object_id = p.OBJECT_ID  
                                            AND i.index_id = p.index_id  
        INNER JOIN msdb.sys.allocation_units a ON p.partition_id = a.container_id  
WHERE   t.type_desc = 'USER_TABLE'  
        AND i.index_id <= 1  --- Heap\ CLUSTERED
        AND t.NAME='MYTableName' -- Replace with valid table name
GROUP BY sc.name + '.' + t.NAME,  
        i.[object_id],i.index_id, i.name, p.[Rows]  
ORDER BY ( SUM(a.total_pages) * 8 ) / 1024 DESC  

Przejdź do bazy danych, następnie kliknij prawym przyciskiem myszy i kliknij raporty, następnie standardowe raporty, a następnie użycie dysku według tabeli. To da ci wszystkie pliki w tej bazie danych oraz ich rekordy, dane, indeksy itp

możesz użyć następującego skryptu, który oblicza objętość dla każdej tabeli i inny zestaw wyników dla całej bazy danych

    SET NOCOUNT ON 
    IF OBJECT_ID('tempdb..#SpaceUsed') IS NOT NULL DROP TABLE #SpaceUsed

    CREATE TABLE #SpaceUsed 
    (
    TableName sysname ,
    [Rows] int ,
    [Reserved] varchar(20),
    [Data] varchar(20),
    [Index_Size] varchar(20),
    [Unused] varchar(20),
    [Reserved_KB] bigint,
    [Data_KB] bigint,
    [Index_Size_KB] bigint,
    [Unused_KB] bigint
    )

    DECLARE @CMD NVARCHAR(MAX) =''
    SELECT @CMD +='EXEC sp_spaceused ' +  ''''+QUOTENAME(TABLE_SCHEMA)+'.'+ QUOTENAME(TABLE_NAME)+''''+';'+CHAR(10)
    FROM INFORMATION_SCHEMA.TABLES 
    --PRINT @CMD

     INSERT INTO #SpaceUsed (TableName ,[Rows] , [Reserved], [Data] , [Index_Size] , [Unused] )
     EXEC sp_executesql @CMD



     UPDATE #SpaceUsed 
     SET [Reserved_KB] = CONVERT(BIGINT,RTRIM(LTRIM(REPLACE([Reserved] , ' KB', '')))),
         [Data_KB] = CONVERT(BIGINT,RTRIM(LTRIM(REPLACE([Data] , ' KB', '')))),
         [Index_Size_KB]= CONVERT(BIGINT,RTRIM(LTRIM(REPLACE([Index_Size] , ' KB', '')))),
         [Unused_KB]= CONVERT(BIGINT,RTRIM(LTRIM(REPLACE([Unused] , ' KB', ''))))


     SELECT TableName, [Rows], Reserved_KB , Data_KB , Index_Size_KB , Unused_KB ,  Data_KB / 1024.0 Data_MB , Data_KB / 1024.0 / 1024.0 Data_GB
     FROM #SpaceUsed
     ORDER BY Data_KB DESC 

     SELECT SUM(Reserved_KB) Reserved_KB , SUM(Data_KB) Data_KB, SUM(Index_Size_KB) Index_Size_KB , SUM(Unused_KB) Unused_KB ,SUM(Data_KB / 1024.0) Data_MB , SUM(Data_KB / 1024.0 / 1024.0) Data_GB
     FROM #SpaceUsed

     DROP TABLE #SpaceUsed