DROP USER trwa zbyt długo, gdy jest wielu użytkowników

W wystąpieniu programu SQL Server 2014 z wystarczającą ilością pamięci RAM i szybkimi dyskami ponad 160 użytkowników ma dostęp do bazy danych. Z jakiegoś powodu mi nie wiadomo, uruchomienie polecenia DROP USER [username]w tej bazie danych trwa do 5 sekund na użytkownika.

Ponowne przypisywanie użytkowników do loginów i przywracanie ich uprawnień jest bardzo szybkie.

W kontekście odświeżania baz danych DEV z produkcji muszę usunąć i ponownie utworzyć wszystkich użytkowników baz danych. Tak, więc usunięcie użytkowników bazy danych i ich ponowne utworzenie jest konieczne.

Jak przyspieszyć DROP USERpolecenie?

Pamiętaj, że muszę uruchomić go ponad 160 razy dla instancji, o której piszę.

To jest SQL, którego używam:

DECLARE drop_user_cur CURSOR FOR 
SELECT name FROM #drop_users

OPEN drop_user_cur
FETCH NEXT FROM drop_user_cur INTO @user

WHILE @@FETCH_STATUS = 0
BEGIN
    SET @sql = 'use [' + @db_name + '] DROP USER [' + @user + ']'
    BEGIN TRY
        print @sql
        EXECUTE(@sql)
    END TRY
    BEGIN CATCH
        print 'ERREUR : ' + @sql
    END CATCH
    FETCH NEXT FROM drop_user_cur INTO @user
END

CLOSE drop_user_cur
DEALLOCATE drop_user_cur

Problem nie pochodzi od kursora; to rzeczywiste DROP USERzajmuje do 5 sekund.

Korzystając z sp_whoisactive, typ_wejścia to NULL.

Nie zwracaj uwagi na czas trwania, DROPi CREATE USERbyły prowadzone w WHILEpętli, dlatego mówi więcej niż minutę.

Profiler pokazuje ponad 125 000 odczytów do wykonania DROP USER.

Service Broker nie jest włączony.

Rozwiązaniem tego problemu było włączenie brokera usług w bazie danych.

ALTER DATABASE [Database_name] SET NEW_BROKER WITH ROLLBACK IMMEDIATE;

Po włączeniu brokera usług dla bazy danych użytkownicy zrzucali praktycznie natychmiast.

Kin zapytał, czy broker usług został włączony w poprzednim komentarzu, który skierował mnie na wyszukiwanie we właściwym kierunku.

nie jest to odpowiedź na pytanie, ale argument na całkowite jego oddalenie.

Jeśli dobrze rozumiem twój komentarz:

W kontekście odświeżania baz danych DEV z produkcji muszę usunąć i ponownie utworzyć wszystkich użytkowników baz danych. Tak, więc usunięcie użytkowników bazy danych i ich ponowne utworzenie jest konieczne.

Twoim celem jest skopiowanie danych produkcyjnych do systemu deweloperskiego i pozwolenie, aby działało z takim samym uprawnieniem jak produkcyjne, przy użyciu tych samych nazw użytkowników .

Najszybszą ścieżką jest klonowanie loginów sql z systemu produkcyjnego do systemu deweloperskiego zgodnie z procedurą opisaną przez ms w tym artykule kb .

dzięki procedurze zdefiniowanej przez ms wynik jest taki, że możesz przywrócić bazy danych na serwerze deweloperskim, a pozwolenie działa bez zmian.

Z powodzeniem zastosowałem powyższą procedurę do skopiowania środowiska produkcyjnego SQL 2005 dla obu środowisk testowych i deweloperskich SQL 2012.
Po sklonowaniu użytkowników proste przywracanie bazy danych doprowadziło mnie do pary w pełni działających nowych systemów z aktualnymi danymi.

Ogromną zaletą tego rozwiązania jest to, że aby odświeżyć dane deweloperów, wystarczy przywrócić produkcyjną bazę danych i to wszystko; będziesz musiał dostosować odniesienia, synonimy i tym podobne, ale uprawnienia nie zostaną naruszone.

Oto kod z artykułu, tylko w celach informacyjnych, ale zapoznaj się z artykułem, który zawiera uwagi i szczegóły dotyczące zgodności ze starymi wersjami sql, szczegóły szyfrowania hasła i inne informacje, które mogą zaoszczędzić ci bólu głowy podczas przesyłania loginów między serwerami:

USE master
GO
IF OBJECT_ID ('sp_hexadecimal') IS NOT NULL
  DROP PROCEDURE sp_hexadecimal
GO
CREATE PROCEDURE sp_hexadecimal
    @binvalue varbinary(256),
    @hexvalue varchar (514) OUTPUT
AS
DECLARE @charvalue varchar (514)
DECLARE @i int
DECLARE @length int
DECLARE @hexstring char(16)
SELECT @charvalue = '0x'
SELECT @i = 1
SELECT @length = DATALENGTH (@binvalue)
SELECT @hexstring = '0123456789ABCDEF'
WHILE (@i <= @length)
BEGIN
  DECLARE @tempint int
  DECLARE @firstint int
  DECLARE @secondint int
  SELECT @tempint = CONVERT(int, SUBSTRING(@binvalue,@i,1))
  SELECT @firstint = FLOOR(@tempint/16)
  SELECT @secondint = @tempint - (@firstint*16)
  SELECT @charvalue = @charvalue +
    SUBSTRING(@hexstring, @firstint+1, 1) +
    SUBSTRING(@hexstring, @secondint+1, 1)
  SELECT @i = @i + 1
END

SELECT @hexvalue = @charvalue
GO

IF OBJECT_ID ('sp_help_revlogin') IS NOT NULL
  DROP PROCEDURE sp_help_revlogin
GO
CREATE PROCEDURE sp_help_revlogin @login_name sysname = NULL AS
DECLARE @name sysname
DECLARE @type varchar (1)
DECLARE @hasaccess int
DECLARE @denylogin int
DECLARE @is_disabled int
DECLARE @PWD_varbinary  varbinary (256)
DECLARE @PWD_string  varchar (514)
DECLARE @SID_varbinary varbinary (85)
DECLARE @SID_string varchar (514)
DECLARE @tmpstr  varchar (1024)
DECLARE @is_policy_checked varchar (3)
DECLARE @is_expiration_checked varchar (3)

DECLARE @defaultdb sysname

IF (@login_name IS NULL)
  DECLARE login_curs CURSOR FOR

      SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin FROM 
sys.server_principals p LEFT JOIN sys.syslogins l
      ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name <> 'sa'
ELSE
  DECLARE login_curs CURSOR FOR


      SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin FROM 
sys.server_principals p LEFT JOIN sys.syslogins l
      ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name = @login_name
OPEN login_curs

FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin
IF (@@fetch_status = -1)
BEGIN
  PRINT 'No login(s) found.'
  CLOSE login_curs
  DEALLOCATE login_curs
  RETURN -1
END
SET @tmpstr = '/* sp_help_revlogin script '
PRINT @tmpstr
SET @tmpstr = '** Generated ' + CONVERT (varchar, GETDATE()) + ' on ' + @@SERVERNAME + ' */'
PRINT @tmpstr
PRINT ''
WHILE (@@fetch_status <> -1)
BEGIN
  IF (@@fetch_status <> -2)
  BEGIN
    PRINT ''
    SET @tmpstr = '-- Login: ' + @name
    PRINT @tmpstr
    IF (@type IN ( 'G', 'U'))
    BEGIN -- NT authenticated account/group

      SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' FROM WINDOWS WITH DEFAULT_DATABASE = [' + @defaultdb + ']'
    END
    ELSE BEGIN -- SQL Server authentication
        -- obtain password and sid
            SET @PWD_varbinary = CAST( LOGINPROPERTY( @name, 'PasswordHash' ) AS varbinary (256) )
        EXEC sp_hexadecimal @PWD_varbinary, @PWD_string OUT
        EXEC sp_hexadecimal @SID_varbinary,@SID_string OUT

        -- obtain password policy state
        SELECT @is_policy_checked = CASE is_policy_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name
        SELECT @is_expiration_checked = CASE is_expiration_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name

            SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' WITH PASSWORD = ' + @PWD_string + ' HASHED, SID = ' + @SID_string + ', DEFAULT_DATABASE = [' + @defaultdb + ']'

        IF ( @is_policy_checked IS NOT NULL )
        BEGIN
          SET @tmpstr = @tmpstr + ', CHECK_POLICY = ' + @is_policy_checked
        END
        IF ( @is_expiration_checked IS NOT NULL )
        BEGIN
          SET @tmpstr = @tmpstr + ', CHECK_EXPIRATION = ' + @is_expiration_checked
        END
    END
    IF (@denylogin = 1)
    BEGIN -- login is denied access
      SET @tmpstr = @tmpstr + '; DENY CONNECT SQL TO ' + QUOTENAME( @name )
    END
    ELSE IF (@hasaccess = 0)
    BEGIN -- login exists but does not have access
      SET @tmpstr = @tmpstr + '; REVOKE CONNECT SQL TO ' + QUOTENAME( @name )
    END
    IF (@is_disabled = 1)
    BEGIN -- login is disabled
      SET @tmpstr = @tmpstr + '; ALTER LOGIN ' + QUOTENAME( @name ) + ' DISABLE'
    END
    PRINT @tmpstr
  END

  FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin
   END
CLOSE login_curs
DEALLOCATE login_curs
RETURN 0
GO

Kursor podobny do tego powinien działać

Use DB_name

declare @username varchar(50)
declare user_cursor cursor for select '['+name+']' from sys.database_principals where type in ('u', 's') and principal_id>4
open user_cursor
fetch next from user_cursor into @username
while (@@fetch_status=0)
begin
EXEC sp_dropuser @username
fetch next from user_cursor into @username
end
close user_cursor
deallocate user_cursor
go