kod maszynowy x86-64, 44 bajty
(Ten sam kod maszynowy działa również w trybie 32-bitowym.)
Odpowiedź @Daniela Scheplera była punktem wyjścia do tego, ale ma to co najmniej jeden nowy algorytmiczny pomysł (nie tylko lepszą grę w golfa tego samego pomysłu): kody ASCII dla 'B'( 1000010) i 'X'( 1011000) dają 16 i 2 po maskowaniu0b0010010 .
Więc po wykluczeniu dziesiętnej (niezerowej cyfry wiodącej) i ósemkowej (char after '0'jest mniejsza niż 'B'), możemy po prostu ustawić base = c & 0b0010010i przejść do pętli cyfr.
Można wywoływać za pomocą x86-64 System V as unsigned __int128 parse_cxx14_int(int dummy, const char*rsi); Wyodrębnij wartość zwracaną EDX z górnej połowy unsigned __int128wyniku za pomocą tmp>>64.
.globl parse_cxx14_int
## Input: pointer to 0-terminated string in RSI
## output: integer in EDX
## clobbers: RAX, RCX (base), RSI (points to terminator on return)
parse_cxx14_int:
xor %eax,%eax # initialize high bits of digit reader
cdq # also initialize result accumulator edx to 0
lea 10(%rax), %ecx # base 10 default
lodsb # fetch first character
cmp $'0', %al
jne .Lentry2
# leading zero. Legal 2nd characters are b/B (base 2), x/X (base 16)
# Or NUL terminator = 0 in base 10
# or any digit or ' separator (octal). These have ASCII codes below the alphabetic ranges
lodsb
mov $8, %cl # after '0' have either digit, apostrophe, or terminator,
cmp $'B', %al # or 'b'/'B' or 'x'/'X' (set a new base)
jb .Lentry2 # enter the parse loop with base=8 and an already-loaded character
# else hex or binary. The bit patterns for those letters are very convenient
and $0b0010010, %al # b/B -> 2, x/X -> 16
xchg %eax, %ecx
jmp .Lentry
.Lprocessdigit:
sub $'0' & (~32), %al
jb .Lentry # chars below '0' are treated as a separator, including '
cmp $10, %al
jb .Lnum
add $('0'&~32) - 'A' + 10, %al # digit value = c-'A' + 10. we have al = c - '0'&~32.
# c = al + '0'&~32. val = m+'0'&~32 - 'A' + 10
.Lnum:
imul %ecx, %edx
add %eax, %edx # accum = accum * base + newdigit
.Lentry:
lodsb # fetch next character
.Lentry2:
and $~32, %al # uppercase letters (and as side effect,
# digits are translated to N+16)
jnz .Lprocessdigit # space also counts as a terminator
.Lend:
ret
Zmienione bloki vs. wersja Daniela są (głównie) wcięte mniej niż inne instrukcje. Również główna pętla ma u dołu gałąź warunkową. Okazało się to neutralną zmianą, ponieważ żadna ścieżka nie mogła wpaść na sam szczyt, a dec ecx / loop .Lentrypomysł wejścia do pętli okazał się nie być wygraną po różnym potraktowaniu ósemki. Ale ma mniej instrukcji wewnątrz pętli z pętlą w formie idiomatycznej do {} podczas tworzenia struktury, więc ją zachowałem.
Wiązka testowa Daniela C ++ Daniela działa bez zmian w trybie 64-bitowym z tym kodem, który wykorzystuje tę samą konwencję wywoływania jak jego 32-bitowa odpowiedź.
g++ -Og parse-cxx14.cpp parse-cxx14.s &&
./a.out < tests | diff -u -w - tests.good
Demontaż, w tym bajty kodu maszynowego, które są rzeczywistą odpowiedzią
0000000000000000 <parse_cxx14_int>:
0: 31 c0 xor %eax,%eax
2: 99 cltd
3: 8d 48 0a lea 0xa(%rax),%ecx
6: ac lods %ds:(%rsi),%al
7: 3c 30 cmp $0x30,%al
9: 75 1c jne 27 <parse_cxx14_int+0x27>
b: ac lods %ds:(%rsi),%al
c: b1 08 mov $0x8,%cl
e: 3c 42 cmp $0x42,%al
10: 72 15 jb 27 <parse_cxx14_int+0x27>
12: 24 12 and $0x12,%al
14: 91 xchg %eax,%ecx
15: eb 0f jmp 26 <parse_cxx14_int+0x26>
17: 2c 10 sub $0x10,%al
19: 72 0b jb 26 <parse_cxx14_int+0x26>
1b: 3c 0a cmp $0xa,%al
1d: 72 02 jb 21 <parse_cxx14_int+0x21>
1f: 04 d9 add $0xd9,%al
21: 0f af d1 imul %ecx,%edx
24: 01 c2 add %eax,%edx
26: ac lods %ds:(%rsi),%al
27: 24 df and $0xdf,%al
29: 75 ec jne 17 <parse_cxx14_int+0x17>
2b: c3 retq
Inne zmiany w porównaniu z wersją Daniela obejmują zapisywanie sub $16, %alod wewnątrz pętli cyfr, poprzez użycie więcej subzamiast w testramach wykrywania separatorów oraz cyfr w porównaniu ze znakami alfabetycznymi.
W przeciwieństwie do Daniela każda postać poniżej '0'jest traktowana jako separator, nie tylko '\''. (Z wyjątkiem ' ': and $~32, %al/ jnzw obu naszych pętlach traktuje spację jako terminator, co jest prawdopodobnie wygodne do testowania za pomocą liczby całkowitej na początku linii.)
Każda operacja, która modyfikuje się %alw pętli, ma gałąź używającą flagi ustawioną przez wynik, a każda gałąź przechodzi (lub spada) w inne miejsce.
