Czy są jakieś biblioteki wygładzające sygnał dla Arduino?

Pracuję nad robotem mobilnym sterowanym za pomocą bezprzewodowego łącza 2,4 GHz. Odbiornik jest podłączony do Arduino Uno, który służy na pokładzie jako główny kontroler. Najbardziej krytyczny (i główny) kanał wejściowy pochodzący z odbiornika wytwarza bardzo głośny sygnał, co prowadzi do wielu drobnych zmian na wyjściu siłowników, nawet jeśli nie są one potrzebne.

                    Rysuj dane wejściowe Arduino w odstępie 30 sekund.

Szukam bibliotek, które mogą wykonywać wydajne wygładzanie. Czy są dostępne biblioteki wygładzania sygnału dla Arduino (Uno)?

Microsmooth to lekka biblioteka wygładzania sygnałów, którą obecnie opracowuję.

Nadal nad tym pracujemy, a jego celem jest uczynienie go lekkim pod względem pamięci i szybkości. Biblioteka zawiera wiele filtrów do wygładzania:

• Prosta średnia ruchoma
• Wykładnicza średnia ruchoma
• Skumulowana średnia ruchoma
• Filtr Savitzky Golay
• Algorytm Ramera Douglasa Peckera
• Filtr Kalmogorov Zurbenko

Aby skorzystać z biblioteki, pobierz ją i dodaj do katalogu źródłowego. Dodaj również następujący wiersz do pliku źródłowego:

#include "microsmooth.h"

Wydaje mi się, że w twoim hałaśliwym sygnale widzę wiele skoków hałasu pojedynczej próbki.

Filtr środkowy lepiej pozbywa się skoków hałasu pojedynczej próbki niż jakikolwiek filtr liniowy. (Jest lepszy niż jakikolwiek filtr dolnoprzepustowy, średnia ruchoma, ważona średnia ruchoma itp. Pod względem czasu odpowiedzi i zdolności do ignorowania takich pojedynczych próbek wartości szczytowych hałasu).

W rzeczywistości istnieje wiele bibliotek wygładzających sygnał dla Arduino, z których wiele zawiera filtr mediany.

biblioteki wygładzające sygnał na arduino.cc:

• Paul Badger: gładki cyfrowy filtr dolnoprzepustowy
• Paul Badger: cyfrowy filtr dolnoprzepustowy digitalSmooth z odrzucaniem wartości odstających
• David A. Mellis i Tom Igoe: Samouczek wygładzania
• Majenki: średnia biblioteka

biblioteki wygładzające sygnał w github:

• AsheeshR / Microsmooth
• jeroendoggen: Biblioteka Arduino-filtrująca sygnały
• karlward: biblioteka do filtrowania danych Arduino
• sebnil: FIR-filter-Arduino-Library
• daPhoosa: MedianFilter
• arc12: Zbiór cyfrowych filtrów sygnałowych (przeznaczony do użytku z Arduino)
• sebnil: Robot samobalansujący w Arduino. Zaimplementowane ze sterownikami PID, filtrami FIR, filtrem uzupełniającym.

Czy coś takiego działałoby w twoim robocie? (Mediana z 3 wymaga bardzo małej mocy procesora, a zatem szybkiego):

/*
median_filter.ino
2014-03-25: started by David Cary
*/

int median_of_3( int a, int b, int c ){
    int the_max = max( max( a, b ), c );
    int the_min = min( min( a, b ), c );
    // unnecessarily clever code
    int the_median = the_max ^ the_min ^ a ^ b ^ c;
    return( the_median );
}

int newest = 0;
int recent = 0;
int oldest = 0;

void setup()
{
    Serial.begin(9600);
    // read first value, initialize with it.
    oldest = random(200);
    recent = oldest;
    newest = recent;
    Serial.println("median filter example: ");
}

void loop()
{
    // drop oldest value and shift in latest value
    oldest = recent;
    recent = newest;
    newest = random(200);

    Serial.print("new value: ");
    Serial.print(newest, DEC);

    int median = median_of_3( oldest, recent, newest );

    Serial.print("smoothed value: ");
    Serial.print(median, DEC);
    Serial.println("");

    delay(5000);
}

Czy próbowałeś filtra dolnoprzepustowego? Znalazłem tutaj inny przykład tutaj .

Obie biblioteki mają listę danych odczytywanych z wybranego czujnika analogowego, który jest uśredniany. Każda nowa wartość czujnika jest dodawana do listy, a ostatnia jest wyrzucana w następujący sposób:

List: 3 4 3 3 4 3 5 3 2 3 4 3 
new reading added. old one thrown out
      /--                     /--
List: 5 3 4 3 3 4 3 5 3 2 3 4
list averaged

Możesz to filtrować cyfrowo za pomocą filtra dolnoprzepustowego:

int valueFilt = (1-0.99)*value + 0.99*valueFilt;

Zmień 0,99, aby zmienić częstotliwość odcięcia (bliższa 1.0 to niższa częstotliwość). Rzeczywistym wyrażeniem tej wartości jest exp (-2 * pi * f / fs), gdzie f jest pożądaną częstotliwością odcięcia, a fs jest częstotliwością, z której próbkowane są dane.

Innym rodzajem „filtra cyfrowego” jest filtr zdarzeń. Działa dobrze na danych, które mają wartości odstające; np. 9,9,8,10,9,25,9. Filtr zdarzeń zwraca najczęstszą wartość. Statystycznie jest to tryb.

Średnie statystyczne, takie jak średnia, tryb itp. Można obliczyć za pomocą Biblioteki średniej Arduino .

Przykład wzięty ze strony Arduino Library, o którym mowa:

#include <Average.h>
#define CNT 600
int d[CNT];

void setup()
{
  Serial.begin(9600);
}

void loop()
{
  int i;

  for(i=0; i<CNT; i++)
  {
    d[i] = random(500);
  }  

  Serial.print("Mean: ");
  Serial.print(mean(d,CNT),DEC);
  Serial.print(" Mode: ");
  Serial.print(mode(d,CNT),DEC);
  Serial.print(" Max: ");
  Serial.print(maximum(d,CNT),DEC);
  Serial.print(" Min: ");
  Serial.print(minimum(d,CNT),DEC);
  Serial.print(" Standard deviation: ");
  Serial.print(stddev(d,CNT),4);
  Serial.println("");
  Serial.println("");

  delay(5000);
}