Jak podzielić przychodzący ciąg?

Przesyłam listę pozycji serwomechanizmu poprzez połączenie szeregowe z arduino w następującym formacie

1:90&2:80&3:180

Który byłby analizowany jako:

servoId : Position & servoId : Position & servoId : Position

Jak podzielić te wartości i przekonwertować je na liczby całkowite?

W przeciwieństwie do innych odpowiedzi wolałbym trzymać się z daleka z Stringnastępujących powodów:

• dynamiczne wykorzystanie pamięci (co może szybko doprowadzić do fragmentacji sterty i wyczerpania pamięci )
• dość powolny z powodu operatorów budowy / zniszczenia / przydziału

W środowisku osadzonym, takim jak Arduino (nawet dla Mega, który ma więcej SRAM), wolałbym używać standardowych funkcji C :

• strchr(): wyszukaj znak w ciągu C (tj. char *)
• strtok(): dzieli łańcuch C na podciągi na podstawie znaku separatora
• atoi(): konwertuje ciąg C na int

Doprowadziłoby to do następującego przykładu kodu:

// Calculate based on max input size expected for one command
#define INPUT_SIZE 30
...

// Get next command from Serial (add 1 for final 0)
char input[INPUT_SIZE + 1];
byte size = Serial.readBytes(input, INPUT_SIZE);
// Add the final 0 to end the C string
input[size] = 0;

// Read each command pair 
char* command = strtok(input, "&");
while (command != 0)
{
    // Split the command in two values
    char* separator = strchr(command, ':');
    if (separator != 0)
    {
        // Actually split the string in 2: replace ':' with 0
        *separator = 0;
        int servoId = atoi(command);
        ++separator;
        int position = atoi(separator);

        // Do something with servoId and position
    }
    // Find the next command in input string
    command = strtok(0, "&");
}

Zaletą jest to, że nie następuje dynamiczny przydział pamięci; możesz nawet zadeklarować inputjako zmienną lokalną wewnątrz funkcji, która odczytuje polecenia i wykonuje je; po zwróceniu funkcji inputodzyskiwany jest rozmiar zajmowany przez (w stosie).

Tej funkcji można użyć do rozdzielenia łańcucha na części w zależności od tego, jaki jest znak oddzielający.

String xval = getValue(myString, ':', 0);
String yval = getValue(myString, ':', 1);

Serial.println("Y:" + yval);
Serial.print("X:" + xval);

Konwertuj ciąg na int

int xvalue = stringToNumber(xval);
int yvalue = stringToNumber(yval);

Ta część kodu pobiera ciąg i oddziela go na podstawie danego znaku i zwraca element między znakiem oddzielającym

String getValue(String data, char separator, int index)
{
    int found = 0;
    int strIndex[] = { 0, -1 };
    int maxIndex = data.length() - 1;

    for (int i = 0; i <= maxIndex && found <= index; i++) {
        if (data.charAt(i) == separator || i == maxIndex) {
            found++;
            strIndex[0] = strIndex[1] + 1;
            strIndex[1] = (i == maxIndex) ? i+1 : i;
        }
    }
    return found > index ? data.substring(strIndex[0], strIndex[1]) : "";
}

Możesz zrobić coś takiego, ale weź pod uwagę kilka rzeczy:

Jeśli użyjesz readStringUntil(), poczeka, aż otrzyma postać lub limity czasu. Tak więc, z twoim bieżącym łańcuchem, ostatnia pozycja będzie trwać trochę dłużej, ponieważ musi czekać. Możesz dodać znak &końca, aby uniknąć tego limitu czasu. Możesz łatwo sprawdzić to zachowanie na monitorze, spróbować wysłać ciąg z dodatkowym &i bez dodatkowego, a zobaczysz takie opóźnienie.

Faktycznie nie trzeba indeks serwo, można po prostu wysłać swój ciąg stanowisk i uzyskać indeks serwo przez pozycję w łańcuchu wartości, coś takiego: 90&80&180&. Jeśli korzystasz z indeksu serwomechanizmu, być może chcesz go sprawdzić (przekonwertuj na int, a następnie dopasuj indeks pętli i), aby upewnić się, że nic nie poszło nie tak z twoją wiadomością.

Musisz sprawdzić, czy zwracany ciąg readStringUntilnie jest pusty. Jeśli funkcja przekroczy limit czasu, nie otrzymałeś wystarczającej ilości danych, a zatem każda próba wyodrębnienia intwartości przyniesie dziwne wyniki.

void setup() {
    Serial.begin(9600);
}

void loop() {
    for(int i=1; i<=3; i++) {
        String servo = Serial.readStringUntil(':');
        if(servo != ""){
            //here you could check the servo number
            String pos = Serial.readStringUntil('&');
            int int_pos=pos.toInt();
            Serial.println("Pos");
            Serial.println(int_pos);
        }
    }
}

Możesz użyć Stream.readStringUntil(terminator)podania innego terminatora dla każdej części.

Następnie do każdej części dzwonisz String.toInt

Najprostszym rozwiązaniem jest użycie sscanf () .

  int id1, id2, id3;
  int pos1, pos2, pos3;
  char* buf = "1:90&2:80&3:180";
  int n = sscanf(buf, "%d:%d&%d:%d&%d:%d", &id1, &pos1, &id2, &pos2, &id3, &pos3);
  Serial.print(F("n="));
  Serial.println(n);
  Serial.print(F("id1="));
  Serial.print(id1);
  Serial.print(F(", pos1="));
  Serial.println(pos1);
  Serial.print(F("id2="));
  Serial.print(id2);
  Serial.print(F(", pos2="));
  Serial.println(pos2);
  Serial.print(F("id3="));
  Serial.print(id3);
  Serial.print(F(", pos3="));
  Serial.println(pos3);

Daje to następujące dane wyjściowe:

n=6
id1=1, pos1=90
id2=2, pos2=80
id3=3, pos3=180

Twoje zdrowie!

Zobacz przykład na: https://github.com/BenTommyE/Arduino_getStringPartByNr

// splitting a string and return the part nr index split by separator
String getStringPartByNr(String data, char separator, int index) {
    int stringData = 0;        //variable to count data part nr 
    String dataPart = "";      //variable to hole the return text

    for(int i = 0; i<data.length()-1; i++) {    //Walk through the text one letter at a time
        if(data[i]==separator) {
            //Count the number of times separator character appears in the text
            stringData++;
        } else if(stringData==index) {
            //get the text when separator is the rignt one
            dataPart.concat(data[i]);
        } else if(stringData>index) {
            //return text and stop if the next separator appears - to save CPU-time
            return dataPart;
            break;
        }
    }
    //return text if this is the last part
    return dataPart;
}

String getValue(String data, char separator, int index)
{
    int maxIndex = data.length() - 1;
    int j = 0;
    String chunkVal = "";

    for (int i = 0; i <= maxIndex && j <= index; i++)
    {
        chunkVal.concat(data[i]);

        if (data[i] == separator)
        {
            j++;

            if (j > index)
            {
                chunkVal.trim();
                return chunkVal;
            }

            chunkVal = "";
        }
        else if ((i == maxIndex) && (j < index)) {
            chunkVal = "";
            return chunkVal;
        }
    }   
}

jfpoilpret dostarczył świetną odpowiedź na analizę komend szeregowych na Arduino. Jednak Attiny85 nie ma dwukierunkowego numeru seryjnego - należy użyć SoftwareSerial. W ten sposób portujesz ten sam kod dla Attiny85

#include <SoftwareSerial.h>

// Calculate based on max input size expected for one command
#define INPUT_SIZE 30

// Initialize SoftwareSerial
SoftwareSerial mySerial(3, 4); // RX=PB3, TX=PB4

// Parameter for receiving Serial command (add 1 for final 0)
char input[INPUT_SIZE + 1];

void setup() {
  mySerial.begin(9600);
}

void loop() {
  // We need this counter to simulate Serial.readBytes which SoftwareSerial lacks
  int key = 0;

  // Start receiving command from Serial
  while (mySerial.available()) {
    delay(3);  // Delay to allow buffer to fill, code gets unstable on Attiny85 without this for some reason
    // Don't read more characters than defined
    if (key < INPUT_SIZE && mySerial.available()) {
      input[key] = mySerial.read();
      key += 1;
    }
  }

  if (key > 0) {
    // Add the final 0 to end the C string
    input[key] = 0;

    // Read each command pair
    char* command = strtok(input, "&");
    while (command != 0)
    {
      // Split the command in two values
      char* separator = strchr(command, ':');
      if (separator != 0)
      {
        // Actually split the string in 2: replace ':' with 0
        *separator = 0;
        int servoId = atoi(command);
        ++separator;
        int position = atoi(separator);
      }
      // Find the next command in input string
      command = strtok(0, "&");
    }
  }
}

Schematy Attiny85 dla numerów pinów

Szkic kompiluje się w:

Sketch uses 2244 bytes (27%) of program storage space. Maximum is 8192 bytes.
Global variables use 161 bytes (31%) of dynamic memory, leaving 351 bytes for local variables. Maximum is 512 bytes.

Jest więc dużo miejsca i pamięci na resztę kodu

char str[] = "1:90&2:80&3:180";     // test sample serial input from servo
int servoId;
int position;

char* p = str;
while (sscanf(p, "%d:%d", &servoId, &position) == 2)
{
    // process servoId, position here
    //
    while (*p && *p++ != '&');   // to next id/pos pair
}

void setup() {
Serial.begin(9600);
char str[] ="1:90&2:80";
char * pch;
pch = strtok(str,"&");
printf ("%s\n",pch);

pch = strtok(NULL,"&"); //pch=next value
printf ("%s\n",pch);
}
void loop(){}

Oto metoda Arduino na dzielenie łańcucha jako odpowiedź na pytanie „Jak podzielić łańcuch na podciąg?” zadeklarowane jako duplikat niniejszego pytania.

Celem tego rozwiązania jest analiza szeregu pozycji GPS zapisanych w pliku karty SD . Zamiast otrzymania ciągu od Serial, ciąg jest odczytywany z pliku.

Funkcja StringSplit()parsuje ciąg znaków sLine = "1.12345,4.56789,hello"na 3 ciągi sParams[0]="1.12345", sParams[1]="4.56789"i sParams[2]="hello".

1. String sInput: wiersze wejściowe do przeanalizowania,
2. char cDelim: znak ogranicznika między parametrami,
3. String sParams[]: tablica wyjściowa parametrów,
4. int iMaxParams: maksymalna liczba parametrów,
5. Dane wyjściowe int: liczba przeanalizowanych parametrów,

Funkcja opiera się na String::indexOf()i String::substring():

int StringSplit(String sInput, char cDelim, String sParams[], int iMaxParams)
{
    int iParamCount = 0;
    int iPosDelim, iPosStart = 0;

    do {
        // Searching the delimiter using indexOf()
        iPosDelim = sInput.indexOf(cDelim,iPosStart);
        if (iPosDelim > (iPosStart+1)) {
            // Adding a new parameter using substring() 
            sParams[iParamCount] = sInput.substring(iPosStart,iPosDelim-1);
            iParamCount++;
            // Checking the number of parameters
            if (iParamCount >= iMaxParams) {
                return (iParamCount);
            }
            iPosStart = iPosDelim + 1;
        }
    } while (iPosDelim >= 0);
    if (iParamCount < iMaxParams) {
        // Adding the last parameter as the end of the line
        sParams[iParamCount] = sInput.substring(iPosStart);
        iParamCount++;
    }

    return (iParamCount);
}

A użycie jest bardzo proste:

String sParams[3];
int iCount, i;
String sLine;

// reading the line from file
sLine = readLine();
// parse only if exists
if (sLine.length() > 0) {
    // parse the line
    iCount = StringSplit(sLine,',',sParams,3);
    // print the extracted paramters
    for(i=0;i<iCount;i++) {
        Serial.print(sParams[i]);
    }
    Serial.println("");
}