Kiedy otwieram plik DMG, jak mogę go otworzyć przed oknami?

Ilekroć pobieram .dmgplik, a następnie go otwieram (zwykle z paska pobierania w Chrome), otwiera się w tle. Czy jest jakiś sposób, aby otworzyć go przed moim oknem?

Edytować

Aby to wyjaśnić: Chcę, aby okno DMG wyskakiwało jako aktywne okno.

W Applescript utworzyłem skrypt Action Folder, który może robić dokładnie to, co chcesz. Skopiuj i wklej go do nowego Applescript, i zapisz jako aplikację (bez początkowego dialogu!) Do „/ Library / Scripts / Folder Action Scripts /”. Następnie możesz dołączyć go do dowolnego folderu (najprawdopodobniej do twojego ~ / Pobranych / folderu), klikając prawym przyciskiem myszy folder i wybierając „skonfiguruj akcje folderu” z menu rozwijanego usług. Aktywuj akcje folderu i pozwól skryptowi oglądać folder.

Skrypt zasadniczo reaguje na elementy upuszczone do folderu, do którego jest dołączony, a jeśli upuszczony element jest rodzaju: „Obraz”, dołącza obraz jako wolumin za pomocą narzędzia wiersza polecenia „hdiutil”.

Możesz skonfigurować jego zachowanie, ustawiając właściwości openWindow i makeFrontmost w skrypcie; można to również zrobić poprzez dwukrotne kliknięcie skryptu po zapisaniu go jako aplikacji - w dwóch dialogach zapyta on, jakie powinno być jego standardowe zachowanie.

Mam nadzieję, że to pomoże,

Asmus

 property openWindow : true
 property makeFrontmost : true

 on run

    display dialog "Do you want to bring the Finder to the front after new items are added?" buttons {"Don't Activate", "Activate"} default button 2
    if the button returned of the result is "Don't Activate" then
        set makeFrontmost to false
    else
        set makeFrontmost to true
    end if


    display dialog "Open Folder after adding new files?" buttons {"Don't Open", "Open"} default button 2
    if the button returned of the result is "Don't Open" then
        set openWindow to false
    else
        set openWindow to true
    end if


 end run

 on adding folder items to thisFolder after receiving addedItems

    repeat with i from 1 to number of items in addedItems
        set itemKind to the kind of (info for item i of addedItems) as string

        if itemKind is "Disk Image" then
            set itemPath to (quoted form of POSIX path of item i of addedItems)
            try
                showImage(itemPath)
            end try
        end if

    end repeat

 end adding folder items to


 on showImage(itemPath)

    set volumeMountpointInfo to do shell script "/usr/bin/hdiutil  attach " & itemPath & " | grep Volumes"


    if (openWindow is true) then
        if (makeFrontmost is true) then
            tell application "Finder" to activate
        end if

       set currentDelim to text item delimiters
       set text item delimiters to tab

       set volumeMountpoint to POSIX file (text item 3 of volumeMountpointInfo)

       set text item delimiters to currentDelim

       tell application "Finder" to open folder volumeMountpoint

    end if

 end showImage

====

2. Applescript, aby określić rodzaj pliku upuszczonego do folderu

On adding folder items to thisFolder after receiving addedItems
repeat with i from 1 to number of items in addedItems
    set itemKind to the kind of (info for item i of addedItems) as string
    display dialog itemKind
end repeat
end adding folder items to

Edytowany Musi być „Obrazem dysku”, a nie „Obrazem”

Z tego co wiem, OS X automatycznie wyświetli zawartość obrazu dysku tylko wtedy, gdy jest on tylko do odczytu. Wskazuje na to ołówek z nacięciem w lewym dolnym rogu okna Findera podczas przeglądania zawartości obrazu.

Jeśli chcesz zmienić obraz dysku, aby to zrobić, możesz utworzyć istniejący obraz dysku tylko do odczytu za pomocą Narzędzia dyskowego. Niestety nie zmieni to zachowania nieprawidłowo wyprodukowanych obrazów, które można pobrać z Internetu.

1. Zamontuj obraz dysku, który chcesz automatycznie otworzyć.
2. Otwórz Narzędzie dyskowe, wyszukując je w Spotlight.
3. Wybierz ikonę „Nowy obraz” na pasku narzędzi.
4. Nazwij plik i wybierz „tylko do odczytu” w „Format obrazu”.
5. Kliknij „Zapisz”. Po zamontowaniu tego nowego obrazu automatycznie otworzy się okno Findera.

To prawdopodobnie nie odpowiada również na pytanie w wystarczający sposób, ale ...

Naciśnięcie polecenia i kliknięcie elementu na pasku pobierania spowoduje wyświetlenie elementu w wyszukiwarce. W tym momencie po prostu naciśnięcie klawisza Command-O (lub dwukrotne kliknięcie pliku dmg) zamontuje go i otworzy w nowym oknie na pierwszym planie.