Zmień domyślną nazwę „Nowy folder”

Kiedy tworzymy „nowy folder” w wyszukiwarce, automatycznie nazywa się „folder bez tytułu”.

Czy można zmienić domyślną nazwę folderu na nazwę bieżącej daty, na przykład „20151223”?

Z pomocą AppleScript możesz to osiągnąć.

Otwórz AppleScript Editor, utwórz nowy dokument i wklej następujące skradzione linie:

tell application "Finder"
    try
        if exists Finder window 1 then
            set thisPath to (the target of the front window) as alias
        else
            set thisPath to (path to desktop)
        end if
    on error
        return
    end try
end tell
set x to my the_perfect_datestring()
if x is not "-ERROR" then
    set fullPath to thisPath & x as text
    tell application "Finder"
        try
            --activate
            if not (exists fullPath) then
                set y to make new folder at thisPath with properties {name:x}
            end if
            activate
            open y
        end try
    end tell
end if
on the_perfect_datestring()
    try
        set cd to (the current date)
        set the_year to year of (cd) as number
        set the_month to month of (cd) as number
        set the_day to day of (cd) as number
        if the_month < 10 then set the_month to "0" & the_month
        if the_day < 10 then set the_day to "0" & the_day
        return ((the_year & the_month & the_day) as string)
    on error
        return "-ERROR"
    end try
end the_perfect_datestring

Zapisz plik jako aplikację AppleScript (np. DateFolder.app) gdzieś (np. ~ / Aplikacje).

Otwórz folder i upuść DateFolder.app na pasku narzędzi:

Aby utworzyć folder w otwartym folderze, wystarczy kliknąć ikonę aplikacji na pasku narzędzi. Nowy folder otworzy się automatycznie. Usuń wiersz 22 ze skryptu ( open y), jeśli nie chcesz, aby nowy folder był otwierany. Jeśli dodasz aplikację do Docka i otworzysz ją, utworzy nowy folder w folderze z przodu lub na pulpicie (jeśli żaden folder nie jest otwarty).

Testowane tylko w systemie Mac OS X 10.7.5. Lew!

Aby dodać łącznik i bieżącą godzinę, dodaj następujące wiersze (zastępując wiersz 32-34 w powyższym skrypcie):

        set the_hour to hours of (cd) as number
        set the_minute to minutes of (cd) as number
        set the_second to seconds of (cd) as number
        if the_month < 10 then set the_month to "0" & the_month
        if the_day < 10 then set the_day to "0" & the_day
        if the_hour < 10 then set the_hour to "0" & the_hour
        if the_minute < 10 then set the_minute to "0" & the_minute
        if the_second < 10 then set the_second to "0" & the_second
        return ((the_year & the_month & the_day & "-" & the_hour & the_minute & the_second) as string)