W jakiś sposób ustawić / dodać tagi w pliku z Applescript pod Mavericks?

9

Próbuję przenieść niektóre z moich skryptów z etykiet na tagi pod Mavericks, ale nie mogę znaleźć sposobu na ustawienie / dodanie tagów za pomocą Applescript.

Czy ktoś wie jak to zrobić? O ile mi wiadomo, tagi nie są tak naprawdę nowe, tylko nowe pod względem bycia bardziej centralną częścią zaktualizowanej wyszukiwarki.

applescript mavericks

— Christian A. Strømmen
źródło

7

Możesz użyć xattr. Spowoduje to skopiowanie znaczników z pliku 1 do pliku 2:

xattr -wx com.apple.metadata:_kMDItemUserTags "$(xattr -px com.apple.metadata:_kMDItemUserTags file1)" file2
xattr -wx com.apple.FinderInfo "$(xattr -px com.apple.FinderInfo file1)" file2

Znaczniki są przechowywane na liście właściwości jako pojedyncza tablica ciągów:

$ xattr -p com.apple.metadata:_kMDItemUserTags file3|xxd -r -p|plutil -convert xml1 - -o -
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<array>
    <string>Red
6</string>
    <string>aa</string>
    <string>Orange
7</string>
    <string>Yellow
5</string>
    <string>Green
2</string>
    <string>Blue
4</string>
    <string>Purple
3</string>
    <string>Gray
1</string>
</array>
</plist>

Tagi dla kolorów mają wartości takie jak Red\n6(gdzie \njest wysuw linii).

Jeśli flaga kColor w com.apple.FinderInfo jest wyłączona, Finder nie pokazuje okręgów dla kolorów obok plików. Jeśli flaga kColor jest ustawiona na pomarańczowy, a plik ma czerwony znacznik, Finder pokazuje zarówno czerwone, jak i pomarańczowe kółka. Możesz ustawić flagę kColor za pomocą AppleScript:

do shell script "xattr -w com.apple.metadata:_kMDItemUserTags '(\"Red\\n6\",\"new tag\")' ~/desktop/file4"
tell application "Finder" to set label index of file "file4" of desktop to item 1 of {2, 1, 3, 6, 4, 5, 7}

'("Red\n6","new tag")' to stara składnia plist do tego:

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<array>
    <string>Red
6</string>
    <string>new tag</string>
</array>
</plist>

xattr -p com.apple.FinderInfo file|head -n1|cut -c28-29wypisuje wartość bitów użytych dla flagi kColor. Czerwony to C, pomarańczowy to E, żółty to A, zielony to 4, niebieski to 8, magenta to 6, a szary to 2. (Flaga, która dodaje 1 do wartości, nie jest używana w OS X.)

— Lri
źródło

są „obrazki znaczników” .PNG lub grafika renderowana w kolorze? nie mogłem znaleźć czegoś takiego jak „C.png” na twardym dysku :)

1

Odpowiedź została opublikowana na liście użytkowników Applescript:

http://lists.apple.com/archives/applescript-users/2015/Jan/msg00193.html

cytat z kodu strony napisanego przez Shane'a Stanleya

Możesz to zrobić dość łatwo za pomocą AppleScriptObjC. Oto procedury obsługi do pobierania tagów, ustawiania tagów i dodawania tagów:

use scripting additions
use framework "Foundation"

on returnTagsFor:posixPath -- get the tags
    set aURL to current application's |NSURL|'s fileURLWithPath:posixPath -- make URL
    set {theResult, theTags} to aURL's getResourceValue:(reference) forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
    if theTags = missing value then return {} -- because when there are none, it returns missing value
    return theTags as list
end returnTagsFor:

on setTags:tagList forPath:posixPath -- set the tags, replacing any existing tags
    set aURL to current application's |NSURL|'s fileURLWithPath:posixPath -- make URL
    aURL's setResourceValue:tagList forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
end setTags:forPath:

on addTags:tagList forPath:posixPath -- add to existing tags
    set aURL to current application's |NSURL|'s fileURLWithPath:posixPath -- make URL
    -- get existing tags
    set {theResult, theTags} to aURL's getResourceValue:(reference) forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
    if theTags ≠ missing value then -- add new tags
        set tagList to (theTags as list) & tagList
        set tagList to (current application's NSOrderedSet's orderedSetWithArray:tagList)'s allObjects() -- delete any duplicates
    end if
    aURL's setResourceValue:tagList forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
end addTags:forPath:

Jeśli zapiszesz je w bibliotece skryptów, możesz także użyć ich z Mavericks.

- Shane Stanley www.macosxautomation.com/applescript/apps/

— brandelune
źródło